dev-qt/qtmultimedia/qtmultimedia-5.7.1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit qt5-build
   6
   7 DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
   8
   9 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  10         KEYWORDS="amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
  11 fi
  12
  13 IUSE="alsa gles2 gstreamer gstreamer010 openal pulseaudio qml widgets"
  14 REQUIRED_USE="?? ( gstreamer gstreamer010 )"
  15
  16 RDEPEND="
  17         ~dev-qt/qtcore-${PV}
  18         ~dev-qt/qtgui-${PV}[gles2=]
  19         ~dev-qt/qtnetwork-${PV}
  20         alsa? ( media-libs/alsa-lib )
  21         gstreamer? (
  22                 dev-libs/glib:2
  23                 media-libs/gstreamer:1.0
  24                 media-libs/gst-plugins-bad:1.0
  25                 media-libs/gst-plugins-base:1.0
  26         )
  27         gstreamer010? (
  28                 dev-libs/glib:2
  29                 media-libs/gstreamer:0.10
  30                 media-libs/gst-plugins-bad:0.10
  31                 media-libs/gst-plugins-base:0.10
  32         )
  33         pulseaudio? ( media-sound/pulseaudio )
  34         qml? (
  35                 ~dev-qt/qtdeclarative-${PV}
  36                 gles2? ( ~dev-qt/qtgui-${PV}[egl] )
  37                 openal? ( media-libs/openal )
  38         )
  39         widgets? (
  40                 ~dev-qt/qtopengl-${PV}
  41                 ~dev-qt/qtwidgets-${PV}[gles2=]
  42         )
  43 "
  44 DEPEND="${RDEPEND}
  45         gstreamer? ( x11-proto/videoproto )
  46 "
  47
  48 src_prepare() {
  49         # do not rely on qtbase configuration
  50         sed -i -e 's/contains(QT_CONFIG, \(alsa\|pulseaudio\))://' \
  51                 qtmultimedia.pro || die
  52
  53         qt_use_compile_test alsa
  54         qt_use_compile_test gstreamer
  55         qt_use_compile_test openal
  56         qt_use_compile_test pulseaudio
  57
  58         qt_use_disable_mod qml quick \
  59                 src/src.pro \
  60                 src/plugins/plugins.pro
  61
  62         qt_use_disable_mod widgets widgets \
  63                 src/src.pro \
  64                 src/gsttools/gsttools.pro \
  65                 src/plugins/gstreamer/common.pri
  66
  67         qt5-build_src_prepare
  68 }
  69
  70 src_configure() {
  71         local myqmakeargs=(
  72                 $(usex gstreamer 'GST_VERSION=1.0' '')
  73                 $(usex gstreamer010 'GST_VERSION=0.10' '')
  74         )
  75         qt5-build_src_configure
  76 }