dev-qt/qtmultimedia/qtmultimedia-5.4.2-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit qt5-build
   7
   8 DESCRIPTION="The Multimedia module for the Qt5 framework"
   9
  10 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  11         KEYWORDS="amd64 arm ~hppa ppc64 ~x86"
  12 fi
  13
  14 IUSE="alsa +gstreamer openal opengl pulseaudio qml widgets"
  15
  16 RDEPEND="
  17         >=dev-qt/qtcore-${PV}:5
  18         >=dev-qt/qtgui-${PV}:5
  19         >=dev-qt/qtnetwork-${PV}:5
  20         alsa? ( media-libs/alsa-lib )
  21         gstreamer? (
  22                 media-libs/gstreamer:0.10
  23                 media-libs/gst-plugins-bad:0.10
  24                 media-libs/gst-plugins-base:0.10
  25         )
  26         pulseaudio? ( media-sound/pulseaudio )
  27         qml? (
  28                 >=dev-qt/qtdeclarative-${PV}:5
  29                 openal? ( media-libs/openal )
  30         )
  31         widgets? (
  32                 >=dev-qt/qtwidgets-${PV}:5
  33                 opengl? ( >=dev-qt/qtopengl-${PV}:5 )
  34         )
  35 "
  36 DEPEND="${RDEPEND}
  37         gstreamer? ( x11-proto/videoproto )
  38 "
  39
  40 src_prepare() {
  41         # do not rely on qtbase configuration
  42         sed -i -e 's/contains(QT_CONFIG, \(alsa\|pulseaudio\))://' \
  43                 qtmultimedia.pro || die
  44
  45         qt_use_compile_test alsa
  46         qt_use_compile_test gstreamer
  47         qt_use_compile_test openal
  48         qt_use_compile_test pulseaudio
  49
  50         qt_use_disable_mod opengl opengl \
  51                 src/multimediawidgets/multimediawidgets.pro
  52
  53         qt_use_disable_mod qml quick \
  54                 src/src.pro \
  55                 src/plugins/plugins.pro
  56
  57         qt_use_disable_mod widgets widgets \
  58                 src/src.pro \
  59                 src/gsttools/gsttools.pro \
  60                 src/plugins/gstreamer/common.pri
  61
  62         qt5-build_src_prepare
  63 }