dev-qt/qtmultimedia/qtmultimedia-5.14.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit qt5-build
   6
   7 DESCRIPTION="Multimedia (audio, video, radio, camera) library for the Qt5 framework"
   8
   9 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  10         KEYWORDS="amd64 arm ~arm64 ~hppa ~ppc ppc64 ~sparc ~x86"
  11 fi
  12
  13 IUSE="alsa gles2-only gstreamer openal pulseaudio qml widgets"
  14
  15 RDEPEND="
  16         ~dev-qt/qtcore-${PV}
  17         ~dev-qt/qtgui-${PV}[gles2-only=]
  18         ~dev-qt/qtnetwork-${PV}
  19         alsa? ( media-libs/alsa-lib )
  20         gstreamer? (
  21                 dev-libs/glib:2
  22                 media-libs/gstreamer:1.0
  23                 media-libs/gst-plugins-bad:1.0
  24                 media-libs/gst-plugins-base:1.0
  25         )
  26         pulseaudio? ( media-sound/pulseaudio[glib] )
  27         qml? (
  28                 ~dev-qt/qtdeclarative-${PV}
  29                 gles2-only? ( ~dev-qt/qtgui-${PV}[egl] )
  30                 openal? ( media-libs/openal )
  31         )
  32         widgets? (
  33                 ~dev-qt/qtopengl-${PV}
  34                 ~dev-qt/qtwidgets-${PV}[gles2-only=]
  35         )
  36 "
  37 DEPEND="${RDEPEND}
  38         gstreamer? ( x11-base/xorg-proto )
  39 "
  40
  41 src_prepare() {
  42         sed -i -e '/CONFIG\s*+=/ s/optimize_full//' \
  43                 src/multimedia/multimedia.pro || die
  44
  45         qt_use_disable_config openal openal \
  46                 src/imports/imports.pro
  47
  48         qt_use_disable_mod qml quick \
  49                 src/src.pro \
  50                 src/plugins/plugins.pro
  51
  52         qt_use_disable_mod widgets widgets \
  53                 src/src.pro \
  54                 src/gsttools/gsttools.pro \
  55                 src/plugins/gstreamer/common.pri
  56
  57         qt5-build_src_prepare
  58 }
  59
  60 src_configure() {
  61         local myqmakeargs=(
  62                 --
  63                 $(qt_use alsa)
  64                 $(qt_use gstreamer)
  65                 $(qt_use pulseaudio)
  66         )
  67         qt5-build_src_configure
  68 }