dev-qt/qtcore/qtcore-4.8.6-r2.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit qt4-build-multilib
   7
   8 DESCRIPTION="Cross-platform application development framework"
   9 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd"
  10 IUSE="+glib iconv icu qt3support ssl"
  11
  12 DEPEND="
  13         >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
  14         glib? ( dev-libs/glib:2[${MULTILIB_USEDEP}] )
  15         iconv? ( >=virtual/libiconv-0-r2[${MULTILIB_USEDEP}] )
  16         icu? ( dev-libs/icu:=[${MULTILIB_USEDEP}] )
  17         ssl? ( >=dev-libs/openssl-1.0.1h-r2:0[${MULTILIB_USEDEP}] )
  18 "
  19 RDEPEND="${DEPEND}"
  20 PDEPEND="
  21         ~dev-qt/qttranslations-${PV}
  22         qt3support? ( ~dev-qt/qtgui-${PV}[aqua=,debug=,glib=,qt3support,${MULTILIB_USEDEP}] )
  23 "
  24
  25 MULTILIB_WRAPPED_HEADERS=(
  26         /usr/include/qt4/Qt/qconfig.h
  27         /usr/include/qt4/QtCore/qconfig.h
  28 )
  29
  30 PATCHES=(
  31         "${FILESDIR}/${PN}-4.8.5-honor-ExcludeSocketNotifiers-in-glib-event-loop.patch" # bug 514968
  32         "${FILESDIR}/${PN}-4.8.5-qeventdispatcher-recursive.patch" # bug 514968
  33         "${FILESDIR}/${PN}-4.8.6-QNAM-corruptions-fix.patch" # bug 548622
  34         "${FILESDIR}/${PN}-4.8.6-moc-boost-1.60.patch" # bug 556104
  35 )
  36
  37 QT4_TARGET_DIRECTORIES="
  38         src/tools/bootstrap
  39         src/tools/moc
  40         src/tools/rcc
  41         src/tools/uic
  42         src/corelib
  43         src/network
  44         src/xml
  45         src/plugins/codecs/cn
  46         src/plugins/codecs/jp
  47         src/plugins/codecs/kr
  48         src/plugins/codecs/tw
  49         tools/linguist/lconvert
  50         tools/linguist/lrelease
  51         tools/linguist/lupdate"
  52
  53 QCONFIG_DEFINE="QT_ZLIB"
  54
  55 src_prepare() {
  56         qt4-build-multilib_src_prepare
  57
  58         # bug 172219
  59         sed -i -e "s:CXXFLAGS.*=:CXXFLAGS=${CXXFLAGS} :" \
  60                 -e "s:LFLAGS.*=:LFLAGS=${LDFLAGS} :" \
  61                 qmake/Makefile.unix || die "sed qmake/Makefile.unix failed"
  62
  63         # bug 427782
  64         sed -i -e '/^CPPFLAGS\s*=/ s/-g //' \
  65                 qmake/Makefile.unix || die "sed CPPFLAGS in qmake/Makefile.unix failed"
  66         sed -i -e 's/setBootstrapVariable QMAKE_CFLAGS_RELEASE/QMakeVar set QMAKE_CFLAGS_RELEASE/' \
  67                 -e 's/setBootstrapVariable QMAKE_CXXFLAGS_RELEASE/QMakeVar set QMAKE_CXXFLAGS_RELEASE/' \
  68                 configure || die "sed configure setBootstrapVariable failed"
  69 }
  70
  71 multilib_src_configure() {
  72         local myconf=(
  73                 -no-accessibility -no-xmlpatterns -no-multimedia -no-audio-backend -no-phonon
  74                 -no-phonon-backend -no-svg -no-webkit -no-script -no-scripttools -no-declarative
  75                 -system-zlib -no-gif -no-libtiff -no-libpng -no-libmng -no-libjpeg
  76                 -no-cups -no-dbus -no-gtkstyle -no-nas-sound -no-opengl -no-openvg
  77                 -no-sm -no-xshape -no-xvideo -no-xsync -no-xinerama -no-xcursor -no-xfixes
  78                 -no-xrandr -no-xrender -no-mitshm -no-fontconfig -no-freetype -no-xinput -no-xkb
  79                 $(qt_use glib)
  80                 $(qt_use iconv)
  81                 $(qt_use icu)
  82                 $(use ssl && echo -openssl-linked || echo -no-openssl)
  83                 $(qt_use qt3support)
  84         )
  85         qt4_multilib_src_configure
  86 }