dev-qt/qt-mobility/qt-mobility-1.2.2_p20130703-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit multilib qt4-r2
   8
   9 DESCRIPTION="Additional Qt APIs for mobile devices and desktop platforms"
  10 HOMEPAGE="http://doc-snapshots.qt.io/qt-mobility/index.html"
  11 SRC_URI="https://dev.gentoo.org/~pesa/distfiles/${P}.tar.xz"
  12 LICENSE="LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="amd64 ~arm ~ppc ~ppc64 x86"
  15
  16 QT_MOBILITY_MODULES=(connectivity +contacts feedback gallery location
  17                 messaging multimedia organizer publishsubscribe
  18                 sensors serviceframework systeminfo versit)
  19 IUSE="bluetooth debug doc networkmanager pulseaudio qml +tools
  20         ${QT_MOBILITY_MODULES[@]}"
  21
  22 REQUIRED_USE="
  23         || ( ${QT_MOBILITY_MODULES[@]#[+-]} )
  24         versit? ( contacts )
  25 "
  26
  27 RDEPEND="
  28         >=dev-qt/qtcore-4.8.0:4
  29         connectivity? (
  30                 >=dev-qt/qtdbus-4.8.0:4
  31                 bluetooth? ( net-wireless/bluez )
  32         )
  33         contacts? ( >=dev-qt/qtgui-4.8.0:4 )
  34         gallery? ( >=dev-qt/qtdbus-4.8.0:4 )
  35         location? (
  36                 >=dev-qt/qtdeclarative-4.8.0:4
  37                 >=dev-qt/qtgui-4.8.0:4
  38                 >=dev-qt/qtsql-4.8.0:4[sqlite]
  39         )
  40         messaging? ( >=net-libs/qmf-4.0 )
  41         multimedia? (
  42                 >=dev-qt/qtgui-4.8.0-r4:4[xv]
  43                 >=dev-qt/qtopengl-4.8.0:4
  44                 media-libs/alsa-lib
  45                 media-libs/gstreamer:0.10
  46                 media-libs/gst-plugins-bad:0.10
  47                 media-libs/gst-plugins-base:0.10
  48                 x11-libs/libX11
  49                 x11-libs/libXext
  50                 x11-libs/libXv
  51                 pulseaudio? ( media-sound/pulseaudio[alsa] )
  52         )
  53         publishsubscribe? (
  54                 tools? ( >=dev-qt/qtgui-4.8.0:4 )
  55         )
  56         qml? ( >=dev-qt/qtdeclarative-4.8.0:4 )
  57         serviceframework? (
  58                 >=dev-qt/qtdbus-4.8.0:4
  59                 >=dev-qt/qtsql-4.8.0:4[sqlite]
  60                 tools? ( >=dev-qt/qtgui-4.8.0:4 )
  61         )
  62         systeminfo? (
  63                 >=dev-qt/qtdbus-4.8.0:4
  64                 >=dev-qt/qtgui-4.8.0:4
  65                 sys-apps/util-linux
  66                 virtual/libudev:=
  67                 x11-libs/libX11
  68                 x11-libs/libXrandr
  69                 bluetooth? ( net-wireless/bluez )
  70                 networkmanager? ( net-misc/networkmanager )
  71         )
  72         versit? ( >=dev-qt/qtgui-4.8.0:4 )
  73 "
  74 DEPEND="${RDEPEND}
  75         virtual/pkgconfig
  76         doc? ( >=dev-qt/qthelp-4.8.0:4 )
  77         multimedia? (
  78                 sys-kernel/linux-headers
  79                 x11-proto/videoproto
  80         )
  81         systeminfo? ( sys-kernel/linux-headers )
  82 "
  83
  84 src_prepare() {
  85         qt4-r2_src_prepare
  86
  87         # disable building of code snippets in doc/
  88         # and translations (they aren't actually translated)
  89         sed -i -re '/SUBDIRS \+= (doc|translations)/d' qtmobility.pro || die
  90
  91         # fix automagic dependency on qt-declarative
  92         if ! use qml; then
  93                 sed -i -e '/SUBDIRS += declarative/d' plugins/plugins.pro || die
  94         fi
  95 }
  96
  97 src_configure() {
  98         # figure out which modules to build
  99         local modules=
 100         for mod in "${QT_MOBILITY_MODULES[@]#[+-]}"; do
 101                 use ${mod} && modules+="${mod} "
 102         done
 103
 104         # custom configure script
 105         local myconf=(
 106                 ./configure
 107                 -prefix "${EPREFIX}/usr"
 108                 -headerdir "${EPREFIX}/usr/include/qt4"
 109                 -libdir "${EPREFIX}/usr/$(get_libdir)/qt4"
 110                 -plugindir "${EPREFIX}/usr/$(get_libdir)/qt4/plugins"
 111                 $(use debug && echo -debug || echo -release)
 112                 $(use doc || echo -no-docs)
 113                 $(use tools || echo -no-tools)
 114                 -modules "${modules}"
 115         )
 116         echo "${myconf[@]}"
 117         "${myconf[@]}" || die "configure failed"
 118
 119         # fix automagic dependency on bluez
 120         if ! use bluetooth; then
 121                 sed -i -e '/^bluez_enabled =/s:yes:no:' config.pri || die
 122         fi
 123
 124         # fix automagic dependency on networkmanager
 125         if ! use networkmanager; then
 126                 sed -i -e '/^networkmanager_enabled =/s:yes:no:' config.pri || die
 127         fi
 128
 129         # fix automagic dependency on pulseaudio
 130         if ! use pulseaudio; then
 131                 sed -i -e '/^pulseaudio_enabled =/s:yes:no:' config.pri || die
 132         fi
 133
 134         eqmake4 -recursive
 135 }
 136
 137 src_compile() {
 138         qt4-r2_src_compile
 139
 140         use doc && emake docs
 141 }
 142
 143 src_install() {
 144         qt4-r2_src_install
 145
 146         if use doc; then
 147                 dodoc -r doc/html
 148                 dodoc doc/qch/qtmobility.qch
 149                 docompress -x /usr/share/doc/${PF}/qtmobility.qch
 150         fi
 151 }