dev-qt/qt-docs/qt-docs-5.12.3_p201904161302.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Qt5 documentation, for use with Qt Creator and other tools"
   7 HOMEPAGE="https://doc.qt.io/"
   8
   9 PV_FULL=${PV/_p/-0-}
  10 PV_NODOTS=$(ver_rs 1-3 '' ${PV/_p*/})
  11 BASE_URI="https://download.qt.io/online/qtsdkrepository/linux_x64/desktop/qt5_${PV_NODOTS}_src_doc_examples/qt.qt5.${PV_NODOTS}.doc"
  12 SRC_URI="${BASE_URI}/${PV_FULL}qt-everywhere-documentation.7z
  13         charts? ( ${BASE_URI}.qtcharts/${PV_FULL}qtcharts-documentation.7z )
  14         datavis? ( ${BASE_URI}.qtdatavis3d/${PV_FULL}qtdatavisualization-documentation.7z )
  15         networkauth? ( ${BASE_URI}.qtnetworkauth/${PV_FULL}qtnetworkauth-documentation.7z )
  16         script? ( ${BASE_URI}.qtscript/${PV_FULL}qtscript-documentation.7z
  17                 ${BASE_URI}.qtscript/${PV_FULL}qtscripttools-documentation.7z )
  18         virtualkeyboard? ( ${BASE_URI}.qtvirtualkeyboard/${PV_FULL}qtvirtualkeyboard-documentation.7z )
  19         webengine? ( ${BASE_URI}.qtwebengine/${PV_FULL}qtwebengine-documentation.7z )
  20 "
  21
  22 LICENSE="FDL-1.3"
  23 SLOT="5"
  24 KEYWORDS="x86"
  25
  26 IUSE="3d bluetooth charts datavis declarative graphicaleffects +html location
  27         multimedia networkauth +qch script sensors virtualkeyboard webengine"
  28 REQUIRED_USE="|| ( html qch )"
  29
  30 BDEPEND="app-arch/p7zip"
  31
  32 S=${WORKDIR}/Docs/Qt-${PV%_p*}
  33
  34 src_prepare() {
  35         default
  36
  37         # bug 597026
  38         rm -r global || die
  39
  40         # bug 602750
  41         rm Makefile || die
  42
  43         use 3d || rm -r qt3d* || die
  44         use bluetooth || rm -r qtbluetooth* || die
  45         use declarative || rm -r qtqml* qtquick* || die
  46         use graphicaleffects || rm -r qtgraphicaleffects* || die
  47         use location || rm -r qtlocation* || die
  48         use multimedia || rm -r qtmultimedia* || die
  49         use sensors || rm -r qtsensors* || die
  50 }
  51
  52 src_install() {
  53         # must be the same as QT5_DOCDIR
  54         local dest=/usr/share/qt5-doc
  55         insinto "${dest}"
  56         use html && doins -r */
  57         use qch && doins *.qch
  58         docompress -x "${dest}"
  59 }