dev-qt/qt-creator/qt-creator-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 LLVM_MAX_SLOT=8
   6 PLOCALES="cs da de fr ja pl ru sl uk zh-CN zh-TW"
   7
   8 inherit llvm qmake-utils virtualx xdg
   9
  10 DESCRIPTION="Lightweight IDE for C++/QML development centering around Qt"
  11 HOMEPAGE="https://doc.qt.io/qtcreator/"
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14
  15 if [[ ${PV} == *9999 ]]; then
  16         inherit git-r3
  17         EGIT_REPO_URI="https://code.qt.io/${PN}/${PN}.git"
  18 else
  19         MY_PV=${PV/_/-}
  20         MY_P=${PN}-opensource-src-${MY_PV}
  21         [[ ${MY_PV} == ${PV} ]] && MY_REL=official || MY_REL=development
  22         SRC_URI="https://download.qt.io/${MY_REL}_releases/${PN/-}/$(ver_cut 1-2)/${MY_PV}/${MY_P}.tar.xz"
  23         KEYWORDS="~amd64 ~arm ~x86"
  24         S=${WORKDIR}/${MY_P}
  25 fi
  26
  27 # TODO: unbundle sqlite, yaml-cpp, and KSyntaxHighlighting
  28
  29 QTC_PLUGINS=(android +autotest baremetal bazaar beautifier boot2qt
  30         '+clang:clangcodemodel|clangformat|clangpchmanager|clangrefactoring|clangtools' clearcase
  31         cmake:cmakeprojectmanager cppcheck ctfvisualizer cvs +designer git glsl:glsleditor +help ios
  32         lsp:languageclient mercurial modeling:modeleditor nim perforce perfprofiler python
  33         qbs:qbsprojectmanager +qmldesigner qmlprofiler qnx remotelinux scxml:scxmleditor serialterminal
  34         silversearcher subversion valgrind winrt)
  35 IUSE="doc systemd test +webengine ${QTC_PLUGINS[@]%:*}"
  36 REQUIRED_USE="
  37         boot2qt? ( remotelinux )
  38         clang? ( test? ( qbs ) )
  39         python? ( lsp )
  40         qnx? ( remotelinux )
  41 "
  42
  43 # minimum Qt version required
  44 QT_PV="5.12.3:5"
  45
  46 CDEPEND="
  47         >=dev-qt/qtconcurrent-${QT_PV}
  48         >=dev-qt/qtcore-${QT_PV}
  49         >=dev-qt/qtdeclarative-${QT_PV}[widgets]
  50         >=dev-qt/qtgui-${QT_PV}
  51         >=dev-qt/qtnetwork-${QT_PV}[ssl]
  52         >=dev-qt/qtprintsupport-${QT_PV}
  53         >=dev-qt/qtquickcontrols-${QT_PV}
  54         >=dev-qt/qtscript-${QT_PV}
  55         >=dev-qt/qtsql-${QT_PV}[sqlite]
  56         >=dev-qt/qtsvg-${QT_PV}
  57         >=dev-qt/qtwidgets-${QT_PV}
  58         >=dev-qt/qtx11extras-${QT_PV}
  59         >=dev-qt/qtxml-${QT_PV}
  60         clang? ( sys-devel/clang:8= )
  61         designer? ( >=dev-qt/designer-${QT_PV} )
  62         help? (
  63                 >=dev-qt/qthelp-${QT_PV}
  64                 webengine? ( >=dev-qt/qtwebengine-${QT_PV}[widgets] )
  65         )
  66         perfprofiler? ( dev-libs/elfutils )
  67         qbs? ( >=dev-util/qbs-1.13.1 )
  68         serialterminal? ( >=dev-qt/qtserialport-${QT_PV} )
  69         systemd? ( sys-apps/systemd:= )
  70 "
  71 DEPEND="${CDEPEND}
  72         >=dev-qt/linguist-tools-${QT_PV}
  73         virtual/pkgconfig
  74         doc? ( >=dev-qt/qdoc-${QT_PV} )
  75         test? (
  76                 >=dev-qt/qtdeclarative-${QT_PV}[localstorage]
  77                 >=dev-qt/qtquickcontrols2-${QT_PV}
  78                 >=dev-qt/qttest-${QT_PV}
  79                 >=dev-qt/qtxmlpatterns-${QT_PV}[qml]
  80         )
  81 "
  82 RDEPEND="${CDEPEND}
  83         sys-devel/gdb[client,python]
  84         bazaar? ( dev-vcs/bzr )
  85         cmake? ( dev-util/cmake )
  86         cppcheck? ( dev-util/cppcheck )
  87         cvs? ( dev-vcs/cvs )
  88         git? ( dev-vcs/git )
  89         mercurial? ( dev-vcs/mercurial )
  90         silversearcher? ( sys-apps/the_silver_searcher )
  91         subversion? ( dev-vcs/subversion )
  92         valgrind? ( dev-util/valgrind )
  93 "
  94 # qt translations must also be installed or qt-creator translations won't be loaded
  95 for x in ${PLOCALES}; do
  96         IUSE+=" l10n_${x}"
  97         RDEPEND+=" l10n_${x}? ( >=dev-qt/qttranslations-${QT_PV} )"
  98 done
  99 unset x
 100
 101 pkg_setup() {
 102         use clang && llvm_pkg_setup
 103 }
 104
 105 src_prepare() {
 106         default
 107
 108         # disable unwanted plugins
 109         for plugin in "${QTC_PLUGINS[@]#[+-]}"; do
 110                 if ! use ${plugin%:*}; then
 111                         einfo "Disabling ${plugin%:*} plugin"
 112                         sed -i -re "s/(^\s+|\s*SUBDIRS\s*\+=.*)\<(${plugin#*:})\>(.*)/\1\3/" \
 113                                 src/plugins/plugins.pro || die "failed to disable ${plugin%:*} plugin"
 114                 fi
 115         done
 116         sed -i -e '/updateinfo/d' src/plugins/plugins.pro || die
 117
 118         # avoid building unused support libraries and tools
 119         if ! use clang; then
 120                 sed -i -e '/clangsupport/d' src/libs/libs.pro || die
 121                 sed -i -e '/clang\(\|pchmanager\|refactoring\)backend/d' src/tools/tools.pro || die
 122         fi
 123         if ! use glsl; then
 124                 sed -i -e '/glsl/d' src/libs/libs.pro || die
 125         fi
 126         if ! use lsp; then
 127                 sed -i -e '/languageserverprotocol/d' src/libs/libs.pro tests/auto/auto.pro || die
 128         fi
 129         if ! use modeling; then
 130                 sed -i -e '/modelinglib/d' src/libs/libs.pro || die
 131         fi
 132         if ! use perfprofiler; then
 133                 rm -rf src/tools/perfparser || die
 134                 if ! use ctfvisualizer && ! use qmlprofiler; then
 135                         sed -i -e '/tracing/d' src/libs/libs.pro tests/auto/auto.pro || die
 136                 fi
 137         fi
 138         if ! use qmldesigner; then
 139                 sed -i -e '/qml2puppet/d' src/tools/tools.pro || die
 140                 sed -i -e '/qmldesigner/d' tests/auto/qml/qml.pro || die
 141         fi
 142         if ! use valgrind; then
 143                 sed -i -e '/valgrindfake/d' src/tools/tools.pro || die
 144                 sed -i -e '/valgrind/d' tests/auto/auto.pro || die
 145         fi
 146
 147         # automagic dep on qtwebengine
 148         if ! use webengine; then
 149                 sed -i -e 's/isEmpty(QT\.webenginewidgets\.name)/true/' src/plugins/help/help.pro || die
 150         fi
 151
 152         # disable broken or unreliable tests
 153         sed -i -e 's/\(manual\|tools\|unit\)//g' tests/tests.pro || die
 154         sed -i -e '/\(dumpers\|namedemangler\)\.pro/d' tests/auto/debugger/debugger.pro || die
 155         sed -i -e '/CONFIG -=/s/$/ testcase/' tests/auto/extensionsystem/pluginmanager/correctplugins1/plugin?/plugin?.pro || die
 156         sed -i -e 's/\<check\>//' tests/auto/qml/codemodel/codemodel.pro || die
 157
 158         # do not install test binaries
 159         sed -i -e '/CONFIG +=/s/$/ no_testcase_installs/' tests/auto/{qttest.pri,json/json.pro} || die
 160
 161         # fix path to some clang headers
 162         sed -i -e "/^CLANG_RESOURCE_DIR\s*=/s:\$\${LLVM_LIBDIR}:${EPREFIX}/usr/lib:" src/shared/clang/clang_defines.pri || die
 163
 164         # fix translations
 165         local lang languages=
 166         for lang in ${PLOCALES}; do
 167                 use l10n_${lang} && languages+=" ${lang/-/_}"
 168         done
 169         sed -i -e "/^LANGUAGES\s*=/s:=.*:=${languages}:" share/qtcreator/translations/translations.pro || die
 170
 171         # remove bundled qbs
 172         rm -rf src/shared/qbs || die
 173 }
 174
 175 src_configure() {
 176         eqmake5 IDE_LIBRARY_BASENAME="$(get_libdir)" \
 177                 IDE_PACKAGE_MODE=1 \
 178                 $(use clang && echo LLVM_INSTALL_DIR="$(get_llvm_prefix ${LLVM_MAX_SLOT})") \
 179                 $(use qbs && echo QBS_INSTALL_DIR="${EPREFIX}/usr") \
 180                 CONFIG+=qbs_disable_rpath \
 181                 CONFIG+=qbs_enable_project_file_updates \
 182                 $(use systemd && echo CONFIG+=journald) \
 183                 $(use test && echo BUILD_TESTS=1)
 184 }
 185
 186 src_test() {
 187         cd tests/auto && virtx default
 188 }
 189
 190 src_install() {
 191         emake INSTALL_ROOT="${ED}/usr" install
 192
 193         dodoc dist/{changes-*,known-issues}
 194
 195         # install documentation
 196         if use doc; then
 197                 emake docs
 198                 # don't use ${PF} or the doc will not be found
 199                 insinto /usr/share/doc/qtcreator
 200                 doins share/doc/qtcreator/qtcreator{,-dev}.qch
 201                 docompress -x /usr/share/doc/qtcreator/qtcreator{,-dev}.qch
 202         fi
 203 }