dev-qt/assistant/assistant-4.8.5.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils qt4-build
   8
   9 DESCRIPTION="Tool for viewing on-line documentation in Qt help file format"
  10 SLOT="4"
  11 if [[ ${QT4_BUILD_TYPE} == live ]]; then
  12         KEYWORDS=""
  13 else
  14         KEYWORDS="alpha amd64 arm ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
  15 fi
  16
  17 IUSE="webkit"
  18
  19 DEPEND="
  20         ~dev-qt/qtcore-${PV}[aqua=,debug=]
  21         ~dev-qt/qtgui-${PV}[aqua=,debug=]
  22         ~dev-qt/qthelp-${PV}[aqua=,debug=]
  23         ~dev-qt/qtsql-${PV}[aqua=,debug=,sqlite]
  24         webkit? ( ~dev-qt/qtwebkit-${PV}[aqua=,debug=] )
  25 "
  26 RDEPEND="${DEPEND}"
  27
  28 PATCHES=(
  29         "${FILESDIR}/${PN}-4.8.2+gcc-4.7.patch"
  30 )
  31
  32 pkg_setup() {
  33         QT4_TARGET_DIRECTORIES="tools/assistant/tools/assistant"
  34         QT4_EXTRACT_DIRECTORIES="
  35                 include
  36                 src
  37                 tools"
  38
  39         qt4-build_pkg_setup
  40 }
  41
  42 src_prepare() {
  43         # bug 401173
  44         use webkit || PATCHES+=("${FILESDIR}/disable-webkit.patch")
  45
  46         qt4-build_src_prepare
  47 }
  48
  49 src_configure() {
  50         myconf+="
  51                 -system-libpng -system-libjpeg -system-zlib
  52                 -no-sql-mysql -no-sql-psql -no-sql-ibase -no-sql-sqlite2 -no-sql-odbc
  53                 -sm -xshape -xsync -xcursor -xfixes -xrandr -xrender -mitshm -xinput -xkb
  54                 -fontconfig -no-multimedia -no-opengl -no-phonon -no-svg -no-xmlpatterns
  55                 $(qt_use webkit)"
  56
  57         qt4-build_src_configure
  58 }
  59
  60 src_install() {
  61         qt4-build_src_install
  62
  63         doicon tools/assistant/tools/assistant/images/assistant.png
  64         make_desktop_entry assistant Assistant assistant 'Qt;Development;Documentation'
  65 }