dev-python/wsgiproxy2/wsgiproxy2-0.4.6.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
   7
   8 inherit distutils-r1
   9
  10 MY_PN="WSGIProxy2"
  11
  12 DESCRIPTION="HTTP proxying tools for WSGI apps"
  13 HOMEPAGE="https://pypi.org/project/WSGIProxy2/"
  14 SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
  15
  16 LICENSE="MIT"
  17 SLOT="0"
  18 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ppc64 ~s390 ~sh ~sparc x86"
  19
  20 RDEPEND="
  21         dev-python/requests[${PYTHON_USEDEP}]
  22         dev-python/six[${PYTHON_USEDEP}]
  23         dev-python/urllib3[${PYTHON_USEDEP}]
  24         dev-python/webob[${PYTHON_USEDEP}]
  25 "
  26 BDEPEND="${RDEPEND}
  27         dev-python/setuptools[${PYTHON_USEDEP}]
  28         test? (
  29                 >=dev-python/webtest-2.0.17[${PYTHON_USEDEP}]
  30                 dev-python/socketpool[${PYTHON_USEDEP}]
  31                 $(python_gen_cond_dep 'dev-python/restkit[${PYTHON_USEDEP}]' -2)
  32         )"
  33 # Tests needing restkit are skipped under py3
  34 # Testing also revealed the suite needs latest webtest
  35
  36 S="${WORKDIR}/${MY_PN}-${PV}"
  37
  38 PATCHES=(
  39         "${FILESDIR}/wsgiproxy2-0.4.6-tests.patch"
  40 )
  41
  42 distutils_enable_sphinx docs
  43 distutils_enable_tests nose
  44
  45 python_prepare_all() {
  46         sed -i '/with-coverage/ d' setup.cfg || die
  47
  48         distutils-r1_python_prepare_all
  49 }