dev-python/tlslite/tlslite-0.4.8.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python2_7 )
   8
   9 inherit distutils-r1 eutils
  10
  11 DESCRIPTION="TLS Lite is a free python library that implements SSL 3.0 and TLS 1.0/1.1"
  12 HOMEPAGE="http://trevp.net/tlslite/ https://pypi.python.org/pypi/tlslite https://github.com/trevp/tlslite"
  13 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  14
  15 LICENSE="BSD public-domain"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 #Refrain for now setting IUSE test and deps of test given test restricted.
  19 IUSE="doc"
  20
  21 DEPEND="
  22         >=dev-libs/cryptlib-3.3.3[python,${PYTHON_USEDEP}]
  23         || (
  24                 dev-python/m2crypto[${PYTHON_USEDEP}]
  25                 dev-python/pycrypto[${PYTHON_USEDEP}]
  26         )"
  27 RDEPEND="${DEPEND}"
  28
  29 RESTRICT="test"
  30
  31 # Tests still hang
  32 python_test() {
  33         cd tests || die
  34         "${PYTHON}" "${S}"/tests/tlstest.py client localhost:4443 . || die
  35         "${PYTHON}" "${S}"/tests/tlstest.py server localhost:4442 . || die
  36 }
  37
  38 python_install_all(){
  39         use doc && HTML_DOCS=( docs/. )
  40         distutils-r1_python_install_all
  41 }
  42
  43 pkg_postinst() {
  44         optfeature "GMP support" dev-python/gmpy
  45 }