dev-python/tagpy/tagpy-2018.1-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 DISTUTILS_IN_SOURCE_BUILD=1
   8 DISTUTILS_USE_SETUPTOOLS=no
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Python Bindings for TagLib"
  12 HOMEPAGE="https://mathema.tician.de//software/tagpy
  13         https://pypi.org/project/tagpy/"
  14 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  15
  16 LICENSE="BSD"
  17 SLOT="0"
  18 KEYWORDS="amd64 ppc ppc64 ~sparc x86"
  19 IUSE="examples"
  20
  21 RDEPEND="
  22         >=dev-libs/boost-1.70:=[python,threads,${PYTHON_USEDEP}]
  23         >=media-libs/taglib-1.8
  24 "
  25 DEPEND="${RDEPEND}"
  26
  27 PATCHES=( "${FILESDIR}/${P}-taglib-1.8.patch" )
  28
  29 python_prepare_all() {
  30         cp "${FILESDIR}"/${P}-readme.rst README.rst || die
  31         distutils-r1_python_prepare_all
  32 }
  33
  34 python_configure() {
  35         local boostpy_ver="${EPYTHON#python}"
  36
  37         "${PYTHON}" configure.py \
  38                 --taglib-inc-dir="${EPREFIX}/usr/include/taglib" \
  39                 --boost-python-libname="boost_python${boostpy_ver/\.}"
  40 }
  41
  42 python_install_all() {
  43         if use examples; then
  44                 docinto examples
  45                 dodoc -r test/*
  46         fi
  47
  48         distutils-r1_python_install_all
  49 }