dev-python/setuptools/setuptools-36.5.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
   6 PYTHON_REQ_USE="xml(+)"
   7
   8 inherit distutils-r1
   9
  10 if [[ ${PV} == "9999" ]]; then
  11         EGIT_REPO_URI="https://github.com/pypa/setuptools.git"
  12         inherit git-r3
  13 else
  14         SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
  15         KEYWORDS="~amd64 ~ia64 ~ppc ~ppc64 ~x86"
  16 fi
  17
  18 DESCRIPTION="Collection of extensions to Distutils"
  19 HOMEPAGE="https://github.com/pypa/setuptools https://pypi.python.org/pypi/setuptools"
  20
  21 LICENSE="MIT"
  22 SLOT="0"
  23 IUSE="test"
  24
  25 RDEPEND="
  26 "
  27 DEPEND="${RDEPEND}
  28         app-arch/unzip
  29         test? (
  30                 dev-python/pip[${PYTHON_USEDEP}]
  31                 >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
  32                 dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
  33                 dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
  34                 >=dev-python/backports-unittest-mock-1.2[${PYTHON_USEDEP}]
  35         )
  36 "
  37 PDEPEND="
  38         >=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]"
  39
  40 # Force in-source build because build system modifies sources.
  41 DISTUTILS_IN_SOURCE_BUILD=1
  42
  43 DOCS=( {CHANGES,README}.rst docs/{easy_install.txt,pkg_resources.txt,setuptools.txt} )
  44
  45 python_prepare_all() {
  46         if [[ ${PV} == "9999" ]]; then
  47                 python_setup
  48                 ${EPYTHON} bootstrap.py || die
  49         fi
  50
  51         # disable tests requiring a network connection
  52         rm setuptools/tests/test_packageindex.py || die
  53
  54         # don't run integration tests
  55         rm setuptools/tests/test_integration.py || die
  56
  57         distutils-r1_python_prepare_all
  58 }
  59
  60 python_test() {
  61         # test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
  62         # It tries to sandbox the test in a tempdir
  63         HOME="${PWD}" py.test --verbose ${PN} || die "Tests failed under ${EPYTHON}"
  64 }
  65
  66 python_install() {
  67         export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
  68         distutils-r1_python_install
  69 }