dev-python/pythondialog/pythondialog-3.3.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 PYTHON_COMPAT=( python3_6 pypy3 )
   6
   7 inherit distutils-r1
   8
   9 DESCRIPTION="A Python module for making simple text/console-mode user interfaces"
  10 HOMEPAGE="http://pythondialog.sourceforge.net/"
  11 SRC_URI="mirror://sourceforge/pythondialog//${PV}/python3-${P}.tar.bz2"
  12
  13 LICENSE="LGPL-2"
  14 SLOT="0"
  15 KEYWORDS="~alpha amd64 ~arm ~ia64 ppc sparc x86"
  16 IUSE="doc examples"
  17
  18 RDEPEND="dev-util/dialog"
  19 DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
  20
  21 python_prepare_all() {
  22         sed -e "/^    'sphinx.ext.intersphinx',/d" -i doc/conf.py || die
  23         distutils-r1_python_prepare_all
  24 }
  25
  26 python_compile_all() {
  27         use doc && emake -C doc html
  28 }
  29
  30 python_install_all() {
  31         if use examples; then
  32                 dodoc -r examples
  33                 docompress -x /usr/share/doc/${PF}/examples
  34         fi
  35         use doc && local HTML_DOCS=( doc/_build/html/. )
  36
  37         distutils-r1_python_install_all
  38 }