dev-python/pylint/pylint-0.25.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python2_7 )
   8
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Python code static checker"
  12 HOMEPAGE="http://www.logilab.org/project/pylint https://pypi.python.org/pypi/pylint"
  13 SRC_URI="ftp://ftp.logilab.org/pub/${PN}/${P}.tar.gz mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  14
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
  18 IUSE="examples"
  19
  20 # Versions specified in __pkginfo__.py.
  21 RDEPEND=">=dev-python/logilab-common-0.53.0[${PYTHON_USEDEP}]
  22         >=dev-python/astng-0.24.3[${PYTHON_USEDEP}]"
  23 DEPEND="${RDEPEND}
  24         dev-python/setuptools[${PYTHON_USEDEP}]"
  25
  26 DISTUTILS_IN_SOURCE_BUILD=1
  27
  28 PATCHES=( "${FILESDIR}"/${PN}-0.26.0-gtktest.patch )
  29
  30 python_test() {
  31         # Test suite broken with Python 3
  32         local msg="Test suite broken with ${EPYTHON}"
  33         if [[ "${EPYTHON}" == python3* ]]; then
  34                 einfo "${msg}"
  35         else
  36                 # https://bitbucket.org/logilab/pylint/issue/11/apparent-regression-in-testsuite-pylint
  37                 # This 'issue' became' declared fixed by accident for version 0.27.0 despite being made citing 0.28.0
  38                 pytest || die "Tests failed under ${EPYTHON}"
  39         fi
  40 }
  41
  42 python_install_all() {
  43         distutils-r1_python_install_all
  44         doman man/{pylint,pyreverse}.1
  45
  46         if use examples; then
  47                 docinto examples
  48                 dodoc examples/*
  49         fi
  50 }
  51
  52 pkg_postinst() {
  53         # Optional dependency on "tk" USE flag would break support for Jython.
  54         elog "pylint-gui script requires dev-lang/python with \"tk\" USE flag enabled."
  55 }