dev-python/pygit2/pygit2-1.0.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_{5,6,7,8} )
   6
   7 inherit distutils-r1
   8
   9 DESCRIPTION="Python bindings for libgit2"
  10 HOMEPAGE="https://github.com/libgit2/pygit2 https://pypi.org/project/pygit2/"
  11 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  12
  13 LICENSE="GPL-2-with-linking-exception"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="test"
  17 RESTRICT="!test? ( test )"
  18
  19 RDEPEND="
  20         =dev-libs/libgit2-0.28*
  21         >=dev-python/cffi-1.0:=[${PYTHON_USEDEP}]
  22 "
  23 DEPEND="${RDEPEND}
  24         test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
  25
  26 src_prepare() {
  27         distutils-r1_src_prepare
  28
  29         # unconditionally prevent it from using network
  30         sed -i -e '/def no_network/a \
  31     return True' test/utils.py || die
  32
  33         # we need to move them away to prevent pytest from forcing '..'
  34         # for imports
  35         mkdir hack || die
  36         mv test hack/ || die
  37         ln -s hack/test test || die
  38 }
  39
  40 python_test() {
  41         pytest -vv hack/test || die
  42 }