dev-python/pycairo/pycairo-1.17.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 PYTHON_COMPAT=( python2_7 python3_{6,7} pypy3 )
   7 PYTHON_REQ_USE="threads(+)"
   8
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Python bindings for the cairo library"
  12 HOMEPAGE="https://www.cairographics.org/pycairo/ https://github.com/pygobject/pycairo"
  13 SRC_URI="https://github.com/pygobject/${PN}/releases/download/v${PV}/${P}.tar.gz"
  14
  15 LICENSE="|| ( LGPL-2.1 MPL-1.1 )"
  16 SLOT="0"
  17 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  18 IUSE="doc examples test"
  19 RESTRICT="!test? ( test )"
  20
  21 RDEPEND="
  22         >=x11-libs/cairo-1.13.1[svg]
  23 "
  24 DEPEND="${RDEPEND}
  25         doc? ( dev-python/sphinx )
  26         test? (
  27                 dev-python/pytest[${PYTHON_USEDEP}]
  28                 dev-python/hypothesis[${PYTHON_USEDEP}]
  29         )
  30 "
  31
  32 PATCHES=(
  33         "${FILESDIR}"/pycairo-1.17.0-pkgconfigdir.patch
  34 )
  35
  36 python_compile_all() {
  37         use doc && emake -C docs
  38 }
  39
  40 python_test() {
  41         esetup.py test
  42 }
  43
  44 python_install() {
  45         distutils-r1_python_install \
  46                 install_pkgconfig --pkgconfigdir="${EPREFIX}/usr/$(get_libdir)/pkgconfig"
  47 }
  48
  49 python_install_all() {
  50         use doc && local HTML_DOCS=( docs/_build/. )
  51
  52         if use examples; then
  53                 dodoc -r examples
  54         fi
  55
  56         distutils-r1_python_install_all
  57 }