dev-python/portend/portend-2.6.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="TCP port monitoring utilities"
  11 HOMEPAGE="https://pypi.org/project/portend/ https://github.com/jaraco/portend"
  12 SRC_URI="mirror://pypi/p/${PN}/${P}.tar.gz"
  13
  14 LICENSE="MIT"
  15 SLOT="0"
  16 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc x86"
  17 IUSE="test"
  18
  19 RDEPEND=">=dev-python/tempora-1.8[${PYTHON_USEDEP}]"
  20
  21 distutils_enable_tests pytest
  22
  23 python_prepare_all() {
  24         # avoid a setuptools_scm dependency
  25         sed -i "s:use_scm_version=True:version='${PV}',name='${PN//-/.}':" setup.py || die
  26         sed -r -i "s:setuptools(_|-)scm[[:space:]]*([><=]{1,2}[[:space:]]*[0-9.a-zA-Z]+|)[[:space:]]*::" \
  27                 setup.cfg || die
  28
  29         # avoid extra test deps
  30         sed -i -r 's: --flake8:: ; s: --black:: ; s: --cov::' pytest.ini || die
  31
  32         distutils-r1_python_prepare_all
  33 }