dev-python/llfuse/llfuse-0.42.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="Python bindings for the low-level FUSE API"
  11 HOMEPAGE="https://python-llfuse.googlecode.com/ https://pypi.python.org/pypi/llfuse"
  12 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.bz2"
  13
  14 LICENSE="LGPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="doc examples"
  18
  19 RDEPEND=">=sys-fs/fuse-2.8.0"
  20 DEPEND="${RDEPEND}
  21         dev-python/setuptools[${PYTHON_USEDEP}]
  22         virtual/pkgconfig"
  23
  24 python_prepare_all() {
  25         # use system setuptools
  26         sed -i '/use_setuptools/d' setup.py || die
  27
  28         distutils-r1_python_prepare_all
  29 }
  30
  31 python_install_all() {
  32         use doc && local HTML_DOCS=( doc/html/. )
  33         use examples && local EXAMPLES=( examples/. )
  34         distutils-r1_python_install_all
  35 }