dev-python/jaraco-packaging/jaraco-packaging-8.1.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( pypy3 python3_{6,7,8} )
   7 DISTUTILS_USE_SETUPTOOLS=rdepend
   8
   9 inherit distutils-r1
  10
  11 MY_PN="${PN/-/.}"
  12 DESCRIPTION="Tools to supplement packaging Python releases"
  13 HOMEPAGE="https://github.com/jaraco/jaraco.packaging"
  14 SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
  15 S="${WORKDIR}/${MY_PN}-${PV}"
  16
  17 LICENSE="MIT"
  18 SLOT="0"
  19 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86"
  20 IUSE="test"
  21 RESTRICT="!test? ( test )"
  22
  23 RDEPEND="
  24         dev-python/importlib_metadata[${PYTHON_USEDEP}]
  25         >=dev-python/namespace-jaraco-2[${PYTHON_USEDEP}]
  26         >=dev-python/six-1.4[${PYTHON_USEDEP}]
  27 "
  28 DEPEND="
  29         dev-python/toml[${PYTHON_USEDEP}]
  30         >=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
  31         test? (
  32                 ${RDEPEND}
  33                 >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
  34         )
  35 "
  36
  37 distutils_enable_sphinx docs '>=dev-python/rst-linker-1.9'
  38
  39 python_test() {
  40         # Skip one test which requires network access
  41         # Override pytest options to skip flake8
  42         PYTHONPATH=. pytest -vv -k "not test_revived_distribution" \
  43                 --override-ini="addopts=--doctest-modules" \
  44                 || die "tests failed with ${EPYTHON}"
  45 }
  46
  47 # https://wiki.gentoo.org/wiki/Project:Python/Namespace_packages#File_collisions_between_pkgutil-style_packages
  48 python_install() {
  49         rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
  50         # note: eclass may default to --skip-build in the future
  51         distutils-r1_python_install --skip-build
  52 }