dev-python/flask-cors/flask-cors-9999.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI=5
   6 PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
   7
   8 inherit distutils-r1
   9
  10 MY_PN="Flask-Cors"
  11 MY_P="${MY_PN}-${PV}"
  12
  13 if [[ "${PV}" == "9999" ]]; then
  14         inherit git-2
  15         EGIT_REPO_URI="git://github.com/wcdolphin/${PN}.git"
  16         SRC_URI=""
  17 else
  18         SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz -> ${P}.tar.gz"
  19 fi
  20
  21 DESCRIPTION="A Flask extension for Cross Origin Resource Sharing (CORS)"
  22 HOMEPAGE="https://github.com/wcdolphin/flask-cors https://pypi.python.org/pypi/Flask-Cors"
  23
  24 LICENSE="MIT"
  25 SLOT="0"
  26 KEYWORDS="~amd64 ~x86"
  27 IUSE="doc test"
  28
  29 RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
  30         dev-python/six[${PYTHON_USEDEP}]"
  31 DEPEND="
  32         dev-python/setuptools[${PYTHON_USEDEP}]
  33         doc? (
  34                 ${RDEPEND}
  35                 >=dev-python/python-docs-2.7.6-r1:2.7
  36                 dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
  37         )
  38         test? (
  39                 ${RDEPEND}
  40                 dev-python/nose[${PYTHON_USEDEP}]
  41         )"
  42
  43 S="${WORKDIR}/${MY_P}"
  44
  45 python_prepare_all() {
  46         if use doc; then
  47                 local PYTHON_DOC_ATOM=$(best_version --host-root dev-python/python-docs:2.7)
  48                 local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
  49                 local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
  50                 local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
  51                 sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" docs/conf.py || die
  52         fi
  53         distutils-r1_python_prepare_all
  54 }
  55
  56 python_compile_all() {
  57         use doc && emake -C docs html
  58 }
  59
  60 python_test() {
  61         esetup.py test
  62 }
  63
  64 python_install_all() {
  65         use doc && local HTML_DOCS=( docs/_build/html/. )
  66
  67         distutils-r1_python_install_all
  68 }