dev-python/cython/cython-0.29.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
   7 PYTHON_REQ_USE="threads(+)"
   8
   9 inherit distutils-r1 toolchain-funcs elisp-common
  10
  11 MY_PN="Cython"
  12 MY_P="${MY_PN}-${PV/_/}"
  13
  14 DESCRIPTION="A Python to C compiler"
  15 HOMEPAGE="https://cython.org https://pypi.org/project/Cython/"
  16 SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
  17
  18 LICENSE="Apache-2.0"
  19 SLOT="0"
  20 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
  21
  22 IUSE="doc emacs test"
  23
  24 RDEPEND="
  25         emacs? ( virtual/emacs )
  26 "
  27 DEPEND="${RDEPEND}
  28         dev-python/setuptools[${PYTHON_USEDEP}]
  29         doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
  30         test? ( dev-python/numpy[${PYTHON_USEDEP}] )"
  31
  32 SITEFILE=50cython-gentoo.el
  33 S="${WORKDIR}/${MY_PN}-${PV%_*}"
  34
  35 python_prepare_all() {
  36         # tests behavior that is illegal in Python 3.7+
  37         # https://github.com/cython/cython/issues/2454
  38         sed -i -e '/with_outer_raising/,/return/d' tests/run/generators_py.py || die
  39
  40         distutils-r1_python_prepare_all
  41 }
  42
  43 python_compile() {
  44         if ! python_is_python3; then
  45                 local CFLAGS="${CFLAGS} -fno-strict-aliasing"
  46                 local CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
  47         fi
  48
  49         # Python gets confused when it is in sys.path before build.
  50         local -x PYTHONPATH=
  51
  52         distutils-r1_python_compile
  53 }
  54
  55 python_compile_all() {
  56         use emacs && elisp-compile Tools/cython-mode.el
  57
  58         use doc && emake -C docs html
  59 }
  60
  61 python_test() {
  62         tc-export CC
  63         # https://github.com/cython/cython/issues/1911
  64         local -x CFLAGS="${CFLAGS} -fno-strict-overflow"
  65         "${PYTHON}" runtests.py -vv --work-dir "${BUILD_DIR}"/tests \
  66                 || die "Tests fail with ${EPYTHON}"
  67 }
  68
  69 python_install_all() {
  70         local DOCS=( CHANGES.rst README.rst ToDo.txt USAGE.txt )
  71         use doc && local HTML_DOCS=( docs/build/html/. )
  72         distutils-r1_python_install_all
  73
  74         if use emacs; then
  75                 elisp-install ${PN} Tools/cython-mode.*
  76                 elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  77         fi
  78 }
  79
  80 pkg_postinst() {
  81         use emacs && elisp-site-regen
  82 }
  83
  84 pkg_postrm() {
  85         use emacs && elisp-site-regen
  86 }