dev-python/cvxopt/cvxopt-1.2.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_6 python3_7 python3_8 )
   7
   8 inherit distutils-r1 toolchain-funcs
   9
  10 DESCRIPTION="Python package for convex optimization"
  11 HOMEPAGE="http://cvxopt.org/ https://github.com/cvxopt/cvxopt"
  12 SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  17 IUSE="doc +dsdp examples fftw +glpk gsl test"
  18 RESTRICT="!test? ( test )"
  19
  20 DEPEND="
  21         virtual/blas
  22         virtual/lapack
  23         sci-libs/amd:0=
  24         sci-libs/cholmod:0=
  25         sci-libs/colamd:0=
  26         sci-libs/suitesparseconfig:0=
  27         sci-libs/umfpack:0=
  28         dsdp? ( sci-libs/dsdp:0= )
  29         fftw? ( sci-libs/fftw:3.0= )
  30         glpk? ( >=sci-mathematics/glpk-4.49:0= )
  31         gsl? ( sci-libs/gsl:0= )"
  32
  33 RDEPEND="${DEPEND}"
  34
  35 BDEPEND="virtual/pkgconfig
  36         doc? ( dev-python/sphinx )
  37         test? ( ${RDEPEND} dev-python/nose[${PYTHON_USEDEP}] )"
  38
  39 python_prepare_all() {
  40         pkg_libs() {
  41                 $(tc-getPKG_CONFIG) --libs-only-l $* | \
  42                         sed -e 's:[ ]-l*\(pthread\|m\)\([ ]\|$\)::g' -e 's:[ ]*$::' | \
  43                         tr ' ' '\n' | sort -u | sed -e "s:^-l\(.*\):\1:g" | \
  44                         tr '\n' ';' | sed -e 's:;$::'
  45         }
  46         pkg_libdir() {
  47                 $(tc-getPKG_CONFIG) --libs-only-L $* | \
  48                         sed -e 's:[ ]*$::' | \
  49                         tr ' ' '\n' | sort -u | sed -e "s:^-L\(.*\):\1:g" | \
  50                         tr '\n' ';' | sed -e 's:;$::'
  51         }
  52         pkg_incdir() {
  53                 $(tc-getPKG_CONFIG) --cflags-only-I $* | \
  54                         sed -e 's:[ ]*$::' | \
  55                         tr ' ' '\n' | sort -u | sed -e "s:^-I\(.*\):\1:g" | \
  56                         tr '\n' ';' | sed -e 's:,$::'
  57         }
  58
  59         # mandatory dependencies
  60         export CVXOPT_BLAS_LIB="$(pkg_libs blas)"
  61         export CVXOPT_BLAS_LIB_DIR="$(pkg_libdir blas)"
  62         export CVXOPT_LAPACK_LIB="$(pkg_libs lapack)"
  63         export CVXOPT_SUITESPARSE_LIB_DIR="$(pkg_libdir umfpack cholmod amd colamd suitesparseconfig)"
  64         export CVXOPT_SUITESPARSE_INC_DIR="$(pkg_incdir umfpack cholmod amd colamd suitesparseconfig)"
  65
  66         # optional dependencies
  67         use dsdp && \
  68                 export CVXOPT_BUILD_DSDP=1 && \
  69                 export CVXOPT_DSDP_LIB_DIR="${EPREFIX}/usr/$(get_libdir)" && \
  70                 export CVXOPT_DSDP_INC_DIR="${EPREFIX}/usr/include"
  71
  72         use fftw && \
  73                 export CVXOPT_BUILD_FFTW=1 && \
  74                 export CVXOPT_FFTW_LIB_DIR="$(pkg_libdir fftw3)" && \
  75                 export CVXOPT_FFTW_INC_DIR="$(pkg_incdir fftw3)"
  76
  77         use glpk && \
  78                 export CVXOPT_BUILD_GLPK=1 && \
  79                 export CVXOPT_GLPK_LIB_DIR="${EPREFIX}/usr/$(get_libdir)" && \
  80                 export CVXOPT_GLPK_INC_DIR="${EPREFIX}/usr/include"
  81
  82         use gsl && \
  83                 export CVXOPT_BUILD_GSL=1 && \
  84                 export CVXOPT_GSL_LIB_DIR="$(pkg_libdir gsl)" && \
  85                 export CVXOPT_GSL_INC_DIR="$(pkg_incdir gsl)"
  86
  87         distutils-r1_python_prepare_all
  88 }
  89
  90 python_compile_all() {
  91         use doc && VARTEXFONTS="${T}/fonts" emake -C doc -B html
  92 }
  93
  94 python_test() {
  95         PYTHONPATH="${BUILD_DIR}"/lib nosetests -v || die
  96 }
  97
  98 python_install_all() {
  99         use doc && HTML_DOCS=( doc/build/html/. )
 100         distutils-r1_python_install_all
 101         if use examples; then
 102                 dodoc -r examples
 103                 docompress -x "/usr/share/doc/${PF}/examples"
 104         fi
 105 }