dev-python/clint/clint-0.3.1-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
   7
   8 inherit distutils-r1 vcs-snapshot
   9
  10 DESCRIPTION="Python Command-line Application Tools"
  11 HOMEPAGE="https://github.com/kennethreitz/clint"
  12 SRC_URI="https://github.com/kennethreitz/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="ISC"
  15 SLOT="0"
  16 KEYWORDS="~amd64"
  17 IUSE="doc examples test"
  18
  19 DEPEND="
  20         doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
  21         test? ( dev-python/pytest[${PYTHON_USEDEP}] )
  22 "
  23 RDEPEND=""
  24
  25 # Prevent install of files to wrong location
  26 PATCHES=( "${FILESDIR}"/${PN}-setup.patch )
  27
  28 python_compile_all() {
  29         use doc && emake -C docs html
  30 }
  31
  32 python_test() {
  33         py.test || die "Tests failed under ${EPYTHON}"
  34 }
  35
  36 python_install_all() {
  37         use doc && local HTML_DOCS=( docs/_build/html/. )
  38         use examples && local EXAMPLES=( examples/. )
  39
  40         distutils-r1_python_install_all
  41 }