dev-python/cffi/cffi-1.11.5.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # DO NOT ADD pypy to PYTHON_COMPAT
   7 # pypy bundles a modified version of cffi. Use python_gen_cond_dep instead.
   8 PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
   9
  10 inherit distutils-r1 toolchain-funcs
  11
  12 DESCRIPTION="Foreign Function Interface for Python calling C code"
  13 HOMEPAGE="https://cffi.readthedocs.io/ https://pypi.org/project/cffi/"
  14 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  15
  16 LICENSE="MIT"
  17 SLOT="0/${PV}"
  18 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  19 IUSE="doc test"
  20
  21 RDEPEND="
  22         virtual/libffi:=
  23         dev-python/pycparser[${PYTHON_USEDEP}]"
  24 DEPEND="${RDEPEND}
  25         virtual/pkgconfig
  26         doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
  27         test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
  28
  29 # Avoid race on _configtest.c (distutils/command/config.py:_gen_temp_sourcefile)
  30 DISTUTILS_IN_SOURCE_BUILD=1
  31
  32 src_configure() {
  33         tc-export PKG_CONFIG
  34 }
  35
  36 python_compile_all() {
  37         use doc && emake -C doc html
  38 }
  39
  40 python_test() {
  41         einfo "$PYTHONPATH"
  42         $PYTHON -c "import _cffi_backend as backend" || die
  43         PYTHONPATH="${PYTHONPATH}" \
  44         py.test -x -v \
  45                 --ignore testing/test_zintegration.py \
  46                 --ignore testing/embedding \
  47                 c/ testing/ \
  48                 || die "Testing failed with ${EPYTHON}"
  49 }
  50
  51 python_install_all() {
  52         use doc && local HTML_DOCS=( doc/build/html/. )
  53         distutils-r1_python_install_all
  54 }