dev-python/bpython/bpython-0.13.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 PYTHON_COMPAT=( python{2_7,3_3,3_4} )
   7 PYTHON_REQ_USE="ncurses"
   8
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Syntax highlighting and autocompletion for the Python interpreter"
  12 HOMEPAGE="http://www.bpython-interpreter.org/ https://bitbucket.org/bobf/bpython/ https://pypi.python.org/pypi/bpython"
  13 SRC_URI="http://www.bpython-interpreter.org/releases/${P}.tar.gz"
  14
  15 LICENSE="MIT"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="doc gtk test"
  19
  20 RDEPEND="
  21         dev-python/pygments[${PYTHON_USEDEP}]
  22         dev-python/requests[${PYTHON_USEDEP}]
  23         dev-python/setuptools[${PYTHON_USEDEP}]
  24         gtk? ( dev-python/pygobject:2[$(python_gen_usedep python2_7)]
  25                 dev-python/pygtk[$(python_gen_usedep python2_7)] )
  26         dev-python/urwid[${PYTHON_USEDEP}]"
  27 DEPEND="${RDEPEND}
  28         doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
  29         test? ( dev-python/mock[${PYTHON_USEDEP}] )"
  30
  31 DOCS=( AUTHORS  CHANGELOG  TODO sample-config sample.theme light.theme )
  32
  33 PATCHES=( "${FILESDIR}"/${PN}-desktop.patch
  34                 "${FILESDIR}"/${PN}-0.13-test_repl.patch )
  35
  36 # Req'd for clean build by each impl
  37 DISTUTILS_IN_SOURCE_BUILD=1
  38
  39 python_compile_all() {
  40         if use doc; then
  41                 sphinx-build -b html -c doc/sphinx/source/ \
  42                         doc/sphinx/source/ doc/sphinx/source/html || die "docs build failed"
  43         fi
  44 }
  45
  46 python_install() {
  47         distutils-r1_python_install
  48         if ! use gtk; then
  49                 rm -f "${D}"usr/bin/bpython-gtk*
  50                 # delete_unneeded_modules() {
  51                 rm -f "${D}$(python_get_sitedir)/bpython/gtk_.py"
  52         fi
  53 }
  54
  55 python_test() {
  56         pushd build/lib > /dev/null
  57         # https://bitbucket.org/bobf/bpython/issue/289/test-failures-in-latest-release-py27-py33
  58         sed -e s':test_enter:_&:' -i bpython/test/test_repl.py || die
  59
  60         "${PYTHON}" -m unittest discover || die
  61         popd > /dev/null
  62 }
  63
  64 python_install_all() {
  65         use doc && local HTML_DOCS=( doc/sphinx/source/html/. )
  66         distutils-r1_python_install_all
  67 }