dev-python/boto3/boto3-1.1.1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 PYTHON_COMPAT=( python2_7 python3_3 python3_4 )
   7
   8 inherit distutils-r1 vcs-snapshot
   9
  10 DESCRIPTION="The AWS SDK for Python"
  11 HOMEPAGE="https://github.com/boto/boto3"
  12 SRC_URI="https://github.com/boto/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="Apache-2.0"
  15 SLOT="0"
  16 KEYWORDS="~amd64"
  17 IUSE="doc test"
  18
  19 CDEPEND="
  20         >=dev-python/botocore-1.1.0[${PYTHON_USEDEP}]
  21         <dev-python/botocore-1.2.0[${PYTHON_USEDEP}]
  22         >=dev-python/jmespath-0.6.2[${PYTHON_USEDEP}]
  23         <dev-python/jmespath-1.0.0[${PYTHON_USEDEP}]
  24         $(python_gen_cond_dep '=dev-python/futures-2.2.0[${PYTHON_USEDEP}]' 'python2_7')
  25 "
  26 DEPEND="
  27         dev-python/setuptools[${PYTHON_USEDEP}]
  28         doc? (
  29                 >=dev-python/guzzle_sphinx_theme-0.7.10[${PYTHON_USEDEP}]
  30                 <dev-python/guzzle_sphinx_theme-0.8[${PYTHON_USEDEP}]
  31                 >=dev-python/sphinx-1.1.3[${PYTHON_USEDEP}]
  32                 <dev-python/sphinx-1.3[${PYTHON_USEDEP}]
  33         )
  34         test? (
  35                 ${CDEPEND}
  36                 dev-python/mock[${PYTHON_USEDEP}]
  37                 dev-python/nose[${PYTHON_USEDEP}]
  38         )
  39 "
  40 RDEPEND="${CDEPEND}"
  41
  42 python_compile_all() {
  43         use doc && emake -C docs html
  44 }
  45
  46 python_test() {
  47         nosetests tests/unit/ tests/functional/ || die "test failed under ${EPYTHON}"
  48 }
  49
  50 python_install_all() {
  51         use doc && local HTML_DOCS=( docs/build/html/. )
  52
  53         distutils-r1_python_install_all
  54 }