dev-python/bcolz/bcolz-1.1.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python{2_7,3_5,3_6} )
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="Provides columnar and compressed data containers"
  11 HOMEPAGE="http://bcolz.blosc.org/"
  12 SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
  13
  14 LICENSE="BSD"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
  17 IUSE="doc test"
  18
  19 RDEPEND="
  20         dev-libs/c-blosc:=
  21         dev-python/numpy[${PYTHON_USEDEP}]
  22 "
  23 DEPEND="${RDEPEND}
  24         dev-python/setuptools[${PYTHON_USEDEP}]
  25         dev-python/setuptools_scm[${PYTHON_USEDEP}]
  26         dev-python/cython[${PYTHON_USEDEP}]
  27         doc? (
  28                 dev-python/sphinx[${PYTHON_USEDEP}]
  29                 dev-python/numpydoc[${PYTHON_USEDEP}]
  30         )
  31         test? ( dev-python/mock[${PYTHON_USEDEP}] )
  32 "
  33
  34 python_compile() {
  35         distutils-r1_python_compile --blosc="${EPREFIX}/usr"
  36 }
  37
  38 python_compile_all() {
  39         use doc && sphinx-build -b html -N docs/ docs/_build/html
  40 }
  41
  42 python_test() {
  43         cd "${BUILD_DIR}"/lib
  44         "${PYTHON}" -c 'import bcolz; bcolz.test()' || die
  45 }
  46
  47 python_install_all() {
  48         use doc && local HTML_DOCS=( docs/_build/html/. )
  49         distutils-r1_python_install_all
  50         dodoc *.rst
  51 }