dev-python/autobahn/autobahn-17.5.1-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
   7
   8 inherit distutils-r1 versionator
   9
  10 MY_P="${PN}-$(replace_version_separator 3 -)"
  11
  12 DESCRIPTION="WebSocket and WAMP for Twisted and Asyncio"
  13 HOMEPAGE="https://pypi.org/project/autobahn
  14         https://crossbar.io/autobahn/
  15         https://github.com/crossbario/autobahn-python"
  16 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
  17
  18 SLOT="0"
  19 LICENSE="MIT"
  20 KEYWORDS="amd64 x86"
  21 IUSE="crypt test"
  22
  23 RDEPEND="
  24         $(python_gen_cond_dep '>=dev-python/trollius-2.0[${PYTHON_USEDEP}]' 'python2_7')
  25         $(python_gen_cond_dep '>=dev-python/futures-3.0.4[${PYTHON_USEDEP}]' 'python2_7')
  26         >=dev-python/cbor-1.0.0[${PYTHON_USEDEP}]
  27         >=dev-python/lz4-0.7.0[${PYTHON_USEDEP}]
  28         crypt? (
  29                 >=dev-python/pyopenssl-16.2.0[${PYTHON_USEDEP}]
  30                 >=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
  31                 >=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
  32                 >=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
  33                 >=dev-python/service_identity-16.0.0
  34         )
  35         >=dev-python/six-1.10.0[${PYTHON_USEDEP}]
  36         >=dev-python/snappy-0.5[${PYTHON_USEDEP}]
  37         >=dev-python/twisted-16.6.0-r2[${PYTHON_USEDEP}]
  38         >=dev-python/txaio-2.6.1[${PYTHON_USEDEP}]
  39         >=dev-python/u-msgpack-2.1[${PYTHON_USEDEP}]
  40         >=dev-python/py-ubjson-0.8.4[${PYTHON_USEDEP}]
  41         >=dev-python/wsaccel-0.6.2[${PYTHON_USEDEP}]
  42         >=dev-python/zope-interface-3.6[${PYTHON_USEDEP}]
  43         "
  44 DEPEND="${RDEPEND}
  45         test? (
  46                 dev-python/mock[${PYTHON_USEDEP}]
  47                 dev-python/pytest[${PYTHON_USEDEP}]
  48                 >=dev-python/pynacl-1.0.1[${PYTHON_USEDEP}]
  49                 >=dev-python/pytrie-0.2[${PYTHON_USEDEP}]
  50                 >=dev-python/pyqrcode-1.1.0[${PYTHON_USEDEP}]
  51         )"
  52
  53 S="${WORKDIR}"/${MY_P}
  54
  55 python_test() {
  56         #esetup.py test
  57         cd "${BUILD_DIR}"/lib || die
  58         py.test -v || die
  59 }
  60
  61 pkg_postinst() {
  62         python_foreach_impl twisted-regen-cache || die
  63 }
  64
  65 pkg_postrm() {
  66         python_foreach_impl twisted-regen-cache || die
  67 }