dev-python/astropy/astropy-1.3.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
   7
   8 inherit distutils-r1 xdg-utils
   9
  10 DESCRIPTION="Core functionality for performing astrophysics with Python"
  11 HOMEPAGE="http://astropy.org/"
  12 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  13
  14 LICENSE="BSD"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  17 IUSE="doc test"
  18
  19 # ply-3.10 incompatible, keep bundled (bug #622802)
  20 #rdep: dev-python/ply[${PYTHON_USEDEP}]
  21 #prep: cp "${FILESDIR}"/astropy-ply.py astropy/extern/ply.py || die
  22
  23 RDEPEND="
  24         dev-libs/expat:0=
  25         dev-python/configobj[${PYTHON_USEDEP}]
  26         >=dev-python/numpy-1.10[${PYTHON_USEDEP}]
  27         dev-python/six[${PYTHON_USEDEP}]
  28         >=sci-astronomy/erfa-1.3:0=
  29         >=sci-astronomy/wcslib-5:0=
  30         >=sci-libs/cfitsio-3.410:0=
  31         sys-libs/zlib:0="
  32 DEPEND="${RDEPEND}
  33         dev-python/astropy-helpers[${PYTHON_USEDEP}]
  34         dev-python/cython[${PYTHON_USEDEP}]
  35         dev-python/setuptools[${PYTHON_USEDEP}]
  36         virtual/pkgconfig
  37         doc? (
  38                 media-gfx/graphviz
  39                 dev-libs/libxml2[${PYTHON_USEDEP}]
  40                 dev-python/h5py[${PYTHON_USEDEP}]
  41                 dev-python/jplephem[${PYTHON_USEDEP}]
  42                 dev-python/matplotlib[${PYTHON_USEDEP}]
  43                 dev-python/pillow[${PYTHON_USEDEP},jpeg(+)]
  44                 dev-python/pytest[${PYTHON_USEDEP}]
  45                 dev-python/pyyaml[${PYTHON_USEDEP}]
  46                 dev-python/sphinx-gallery[${PYTHON_USEDEP}]
  47                 sci-libs/scipy[${PYTHON_USEDEP}]
  48         )
  49         test? (
  50                 dev-libs/libxml2[${PYTHON_USEDEP}]
  51                 dev-python/pillow[${PYTHON_USEDEP},jpeg]
  52                 dev-python/pytest[${PYTHON_USEDEP}]
  53                 dev-python/pytest-mpl[${PYTHON_USEDEP}]
  54                 dev-python/h5py[${PYTHON_USEDEP}]
  55                 sci-libs/scipy[${PYTHON_USEDEP}]
  56         )"
  57
  58 PATCHES=(
  59         "${FILESDIR}"/${PN}-1.3.3-mark-known-failures.patch
  60         "${FILESDIR}"/${PN}-1.3.3-external-python-pkgs.patch
  61 )
  62
  63 python_prepare_all() {
  64         export mydistutilsargs="--offline"
  65         export ASTROPY_USE_SYSTEM_PYTEST=True
  66         #rm -r ${PN}_helpers || die
  67         rm -r cextern/{expat,erfa,cfitsio,wcslib} || die
  68         sed -i -e '/auto_use/s/True/False/' setup.cfg || die
  69         cat >> setup.cfg <<-EOF
  70         [build]
  71         use_system_libraries=1
  72         EOF
  73         xdg_environment_reset
  74         distutils-r1_python_prepare_all
  75 }
  76
  77 python_compile_all() {
  78         if use doc; then
  79                 mkdir -p examples
  80                 touch examples/README.txt || die
  81                 python_setup
  82                 VARTEXFONTS="${T}"/fonts \
  83                         MPLCONFIGDIR="${BUILD_DIR}" \
  84                         PYTHONPATH="${BUILD_DIR}"/lib \
  85                         esetup.py build_docs --no-intersphinx
  86         fi
  87 }
  88
  89 python_test() {
  90         esetup.py test
  91 }
  92
  93 python_install_all() {
  94         use doc && local HTML_DOCS=( docs/_build/html/. )
  95         distutils-r1_python_install_all
  96 }