dev-python/astropy/astropy-1.3.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 python3_{5,6} )
   7
   8 inherit distutils-r1 xdg-utils
   9
  10 DESCRIPTION="Core functionality for performing astrophysics with Python"
  11 HOMEPAGE="https://www.astropy.org/"
  12 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  13
  14 LICENSE="BSD"
  15 SLOT="0"
  16 KEYWORDS="amd64 ~x86 ~amd64-linux ~x86-linux"
  17 IUSE="doc test"
  18 RESTRICT="!test? ( test )"
  19
  20 # ply-3.10 incompatible, keep bundled (bug #622802)
  21 #rdep: dev-python/ply[${PYTHON_USEDEP}]
  22 #prep: cp "${FILESDIR}"/astropy-ply.py astropy/extern/ply.py || die
  23
  24 RDEPEND="
  25         dev-libs/expat:0=
  26         dev-python/configobj[${PYTHON_USEDEP}]
  27         >=dev-python/numpy-1.10[${PYTHON_USEDEP}]
  28         dev-python/six[${PYTHON_USEDEP}]
  29         >=sci-astronomy/erfa-1.3:0=
  30         >=sci-astronomy/wcslib-5:0=
  31         >=sci-libs/cfitsio-3.410:0=
  32         sys-libs/zlib:0="
  33 DEPEND="${RDEPEND}
  34         dev-python/astropy-helpers[${PYTHON_USEDEP}]
  35         dev-python/cython[${PYTHON_USEDEP}]
  36         dev-python/setuptools[${PYTHON_USEDEP}]
  37         virtual/pkgconfig
  38         doc? (
  39                 media-gfx/graphviz
  40                 dev-libs/libxml2[${PYTHON_USEDEP}]
  41                 dev-python/h5py[${PYTHON_USEDEP}]
  42                 dev-python/jplephem[${PYTHON_USEDEP}]
  43                 dev-python/matplotlib[${PYTHON_USEDEP}]
  44                 dev-python/pillow[${PYTHON_USEDEP},jpeg(+)]
  45                 dev-python/pytest[${PYTHON_USEDEP}]
  46                 dev-python/pyyaml[${PYTHON_USEDEP}]
  47                 dev-python/sphinx-gallery[${PYTHON_USEDEP}]
  48                 sci-libs/scipy[${PYTHON_USEDEP}]
  49         )
  50         test? (
  51                 dev-libs/libxml2[${PYTHON_USEDEP}]
  52                 dev-python/pillow[${PYTHON_USEDEP},jpeg]
  53                 dev-python/pytest[${PYTHON_USEDEP}]
  54                 dev-python/pytest-mpl[${PYTHON_USEDEP}]
  55                 dev-python/h5py[${PYTHON_USEDEP}]
  56                 sci-libs/scipy[${PYTHON_USEDEP}]
  57         )"
  58
  59 PATCHES=(
  60         "${FILESDIR}"/${PN}-1.3.3-mark-known-failures.patch
  61         "${FILESDIR}"/${PN}-1.3.3-external-python-pkgs.patch
  62 )
  63
  64 python_prepare_all() {
  65         export mydistutilsargs="--offline"
  66         export ASTROPY_USE_SYSTEM_PYTEST=True
  67         #rm -r ${PN}_helpers || die
  68         rm -r cextern/{expat,erfa,cfitsio,wcslib} || die
  69         sed -i -e '/auto_use/s/True/False/' setup.cfg || die
  70         cat >> setup.cfg <<-EOF
  71         [build]
  72         use_system_libraries=1
  73         EOF
  74         xdg_environment_reset
  75         distutils-r1_python_prepare_all
  76 }
  77
  78 python_compile_all() {
  79         if use doc; then
  80                 mkdir -p examples
  81                 touch examples/README.txt || die
  82                 python_setup
  83                 VARTEXFONTS="${T}"/fonts \
  84                         MPLCONFIGDIR="${BUILD_DIR}" \
  85                         PYTHONPATH="${BUILD_DIR}"/lib \
  86                         esetup.py build_docs --no-intersphinx
  87         fi
  88 }
  89
  90 python_test() {
  91         esetup.py test
  92 }
  93
  94 python_install_all() {
  95         use doc && local HTML_DOCS=( docs/_build/html/. )
  96         distutils-r1_python_install_all
  97 }