dev-python/astropy/astropy-0.4.4.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 PYTHON_COMPAT=( python{2_7,3_3,3_4} )
   8
   9 inherit distutils-r1
  10
  11 DESCRIPTION="Core functionality for performing astrophysics with Python"
  12 HOMEPAGE="http://astropy.org/"
  13 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  14
  15 LICENSE="BSD"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
  18 IUSE="doc test"
  19
  20 RDEPEND="
  21         dev-libs/expat:0=
  22         dev-python/numpy[${PYTHON_USEDEP}]
  23         sci-astronomy/erfa:0=
  24         >=sci-astronomy/wcslib-4.23:0=
  25         >=sci-libs/cfitsio-3.350:0=
  26         sys-libs/zlib:0="
  27 DEPEND="${RDEPEND}
  28         dev-python/astropy-helpers[${PYTHON_USEDEP}]
  29         dev-python/cython[${PYTHON_USEDEP}]
  30         dev-python/setuptools[${PYTHON_USEDEP}]
  31         virtual/pkgconfig
  32         doc? (
  33                 dev-python/matplotlib[${PYTHON_USEDEP}]
  34                 dev-python/sphinx[${PYTHON_USEDEP}]
  35                 media-gfx/graphviz
  36         )
  37         test? (
  38                 dev-libs/libxml2[${PYTHON_USEDEP}]
  39                 dev-python/h5py[${PYTHON_USEDEP}]
  40                 dev-python/matplotlib[${PYTHON_USEDEP}]
  41                 dev-python/pytest[${PYTHON_USEDEP}]
  42                 sci-libs/scipy[${PYTHON_USEDEP}]
  43         )"
  44
  45 python_compile() {
  46         distutils-r1_python_compile --use-system-libraries --offline
  47 }
  48
  49 python_compile_all() {
  50         if use doc; then
  51                 python_export_best
  52                 VARTEXFONTS="${T}"/fonts \
  53                         MPLCONFIGDIR="${BUILD_DIR}" \
  54                         PYTHONPATH="${BUILD_DIR}"/lib \
  55                         esetup.py build_sphinx --offline
  56         fi
  57 }
  58
  59 python_test() {
  60         esetup.py --offline test
  61 }
  62
  63 python_install() {
  64         distutils-r1_python_install --offline
  65 }
  66
  67 python_install_all() {
  68         use doc && local HTML_DOCS=( docs/_build/html/. )
  69         distutils-r1_python_install_all --offline
  70 }