dev-python/appdirs/appdirs-1.4.3-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 # note the patch below
   7 DISTUTILS_USE_SETUPTOOLS=no
   8 PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
   9
  10 inherit distutils-r1
  11
  12 DESCRIPTION="Module for determining appropriate platform-specific dirs"
  13 HOMEPAGE="https://github.com/ActiveState/appdirs"
  14 SRC_URI="https://github.com/ActiveState/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  15
  16 LICENSE="MIT"
  17 SLOT="0"
  18 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  19
  20 PATCHES=( "${FILESDIR}"/${PN}-1.4.3-distutils.patch )
  21
  22 python_test() {
  23         "${PYTHON}" test/test_api.py -v || die "Tests fail with ${EPYTHON}"
  24 }
  25
  26 [[ ${PV} == 1.4.3 ]] || die "Please remove pkg_preinst from the ebuild"
  27 pkg_preinst() {
  28         _remove_egg_info() {
  29                 local pyver="$("${PYTHON}" -c 'import sys; print(sys.version[:3])')"
  30                 local egginfo="${ROOT}$(python_get_sitedir)/${P}-py${pyver}.egg-info"
  31                 if [[ -d ${egginfo} ]]; then
  32                         einfo "Removing ${egginfo}"
  33                         rm -r "${egginfo}" || die
  34                 fi
  35         }
  36         python_foreach_impl _remove_egg_info
  37 }