dev-python/alembic/alembic-1.0.8.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
   6
   7 inherit distutils-r1
   8
   9 DESCRIPTION="database migrations tool, written by the author of SQLAlchemy"
  10 HOMEPAGE="https://bitbucket.org/zzzeek/alembic"
  11 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  12
  13 LICENSE="MIT"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~arm64 x86"
  16 IUSE="test doc"
  17 RESTRICT="!test? ( test )"
  18
  19 # requires.txt cites 'SQLAlchemy>=0.7.3' which is really both old and silly
  20 # because it shatters the testsuite.  If 'someone' cares to adhere to correct form
  21 # and edit to -0.7.3, feel free, and then pick up the pieces.
  22 RDEPEND=">=dev-python/sqlalchemy-0.9.0[${PYTHON_USEDEP}]
  23         dev-python/mako[${PYTHON_USEDEP}]
  24         >=dev-python/python-editor-0.3[${PYTHON_USEDEP}]
  25         dev-python/python-dateutil[${PYTHON_USEDEP}]"
  26 DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
  27         test? ( ${RDEPEND}
  28                 dev-python/nose[${PYTHON_USEDEP}]
  29                 dev-python/mock[${PYTHON_USEDEP}] )"
  30 # For test phase
  31 DISTUTILS_IN_SOURCE_BUILD=1
  32
  33 python_prepare_all() {
  34         # suite passes all if run from source. The residual fail & error are quite erroneous
  35         rm tests/test_script_consumption.py || die
  36
  37         distutils-r1_python_prepare_all
  38 }
  39
  40 python_test() {
  41         ${EPYTHON} run_tests.py || die "Testing failed with ${EPYTHON}"
  42 }
  43
  44 python_install_all() {
  45         use doc && local HTML_DOCS=( docs/. )
  46
  47         distutils-r1_python_install_all
  48 }