dev-php/libvirt-php/libvirt-php-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="7"
   5
   6 PHP_EXT_NAME="libvirt-php"
   7 PHP_EXT_SKIP_PHPIZE="yes"
   8 USE_PHP="php5-6 php7-0 php7-1 php7-2 php7-3"
   9 PHP_EXT_ECONF_ARGS=()
  10
  11 inherit php-ext-source-r3 git-r3 autotools
  12
  13 DESCRIPTION="PHP bindings for libvirt"
  14 HOMEPAGE="http://libvirt.org/php/"
  15 EGIT_REPO_URI="https://gitlab.com/libvirt/libvirt-php.git"
  16
  17 LICENSE="LGPL-2.1"
  18 SLOT="0"
  19 KEYWORDS=""
  20 IUSE="doc"
  21
  22 RDEPEND="app-emulation/libvirt
  23         dev-libs/libxml2"
  24 DEPEND="${RDEPEND}
  25         dev-libs/libxslt
  26         virtual/pkgconfig
  27         doc? ( app-text/xhtml1 )"
  28
  29 RESTRICT="test"
  30 DOCS=( ChangeLog NEWS README )
  31 # Remove the insane check for pecl-imagick which is only used in examples
  32 # and is not called upon in any build
  33 PATCHES=( "${FILESDIR}/remove-imagick-check.patch" )
  34
  35 src_unpack() {
  36         git-r3_src_unpack
  37
  38         # create the default modules directory to be able
  39         # to use the php-ext-source-r3 eclass to configure/build
  40         ln -s src "${S}/modules"
  41 }
  42
  43 src_prepare() {
  44         php-ext-source-r3_src_prepare
  45         local slot
  46         for slot in $(php_get_slots); do
  47                 php_init_slot_env "${slot}"
  48                 eautoreconf
  49         done
  50 }
  51
  52 src_install() {
  53         local slot
  54         for slot in $(php_get_slots); do
  55                 php_init_slot_env ${slot}
  56                 insinto "${EXT_DIR}"
  57                 doins "src/.libs/${PHP_EXT_NAME}.so"
  58         done
  59         php-ext-source-r3_createinifiles
  60         einstalldocs
  61         if use doc ; then
  62                 docinto /usr/share/doc/${PF}/html
  63                 dodoc -r docs/*
  64         fi
  65 }