dev-php/libvirt-php/libvirt-php-0.5.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="7"
   5
   6 PHP_EXT_NAME="libvirt-php"
   7 PHP_EXT_SKIP_PHPIZE="yes"
   8 USE_PHP="php5-6 php7-0 php7-1 php7-2 php7-3"
   9 PHP_EXT_ECONF_ARGS=()
  10
  11 inherit php-ext-source-r3 autotools
  12
  13 DESCRIPTION="PHP bindings for libvirt"
  14 HOMEPAGE="http://libvirt.org/php/"
  15 SRC_URI="http://libvirt.org/sources/php/${P}.tar.gz"
  16
  17 LICENSE="LGPL-2.1"
  18 SLOT="0"
  19 KEYWORDS="~amd64"
  20 IUSE="doc"
  21
  22 RDEPEND="app-emulation/libvirt
  23         dev-libs/libxml2"
  24 DEPEND="${RDEPEND}
  25         dev-libs/libxslt
  26         virtual/pkgconfig
  27         doc? ( app-text/xhtml1 )"
  28
  29 RESTRICT="test"
  30 # ChangeLog and NEWS are empty files
  31 DOCS=( AUTHORS README )
  32 # Remove the insane check for pecl-imagick which is only used in examples
  33 # and is not called upon in any build
  34 PATCHES=( "${FILESDIR}/remove-imagick-check.patch" )
  35
  36 src_unpack() {
  37         default
  38
  39         # create the default modules directory to be able
  40         # to use the php-ext-source-r3 eclass to configure/build
  41         ln -s src "${S}/modules"
  42 }
  43
  44 src_prepare() {
  45         php-ext-source-r3_src_prepare
  46         local slot
  47         for slot in $(php_get_slots); do
  48                 php_init_slot_env "${slot}"
  49                 eautoreconf
  50         done
  51 }
  52
  53 src_install() {
  54         local slot
  55         for slot in $(php_get_slots); do
  56                 php_init_slot_env ${slot}
  57                 insinto "${EXT_DIR}"
  58                 doins "src/.libs/${PHP_EXT_NAME}.so"
  59         done
  60         php-ext-source-r3_createinifiles
  61         einstalldocs
  62         if use doc ; then
  63                 docinto /usr/share/doc/${PF}/html
  64                 dodoc -r docs/*
  65         fi
  66 }