dev-perl/Perl-Critic/Perl-Critic-1.130.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 DIST_AUTHOR=PETDANCE
   7 DIST_VERSION=1.130
   8 inherit perl-module elisp-common
   9
  10 DESCRIPTION="Critique Perl source code for best-practices"
  11
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 ppc ~ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris"
  14 IUSE="test minimal examples emacs"
  15 RESTRICT="!test? ( test )"
  16 SITEFILE="50${PN}-gentoo.el"
  17 RDEPEND="
  18         >=dev-perl/B-Keywords-1.50.0
  19         virtual/perl-Carp
  20         >=dev-perl/Config-Tiny-2
  21         >=dev-perl/Email-Address-1.889.0
  22         >=dev-perl/Exception-Class-1.230.0
  23         >=virtual/perl-Exporter-5.630.0
  24         dev-perl/File-HomeDir
  25         virtual/perl-File-Path
  26         virtual/perl-File-Spec
  27         virtual/perl-File-Temp
  28         dev-perl/File-Which
  29         virtual/perl-Getopt-Long
  30         dev-perl/IO-String
  31         >=dev-perl/List-MoreUtils-0.190.0
  32         >=dev-perl/Module-Pluggable-3.100.0
  33         >=dev-perl/PPI-1.224
  34         >=dev-perl/PPIx-Regexp-0.27.0
  35         >=dev-perl/PPIx-Utilities-1.1.0
  36         virtual/perl-Pod-Parser
  37         >=dev-perl/Pod-Spell-1
  38         >=dev-perl/Readonly-2
  39         virtual/perl-Scalar-List-Utils
  40         >=dev-perl/String-Format-1.130.0
  41         dev-perl/Task-Weaken
  42         >=virtual/perl-Term-ANSIColor-2.20.0
  43         >=virtual/perl-Test-Simple-0.920.0
  44         >=virtual/perl-Text-ParseWords-3
  45         dev-perl/Perl-Tidy
  46         >=virtual/perl-version-0.770.0
  47         emacs? ( >=app-editors/emacs-23.1:* )
  48 "
  49 DEPEND="${RDEPEND}
  50         >=dev-perl/Module-Build-0.402.400
  51         test? (
  52                 dev-perl/Test-Deep
  53                 !minimal? (
  54                         dev-perl/Test-Memory-Cycle
  55                 )
  56         )"
  57
  58 src_compile() {
  59         perl-module_src_compile
  60         if use emacs; then
  61                 elisp-compile extras/perlcritic.el
  62         fi
  63 }
  64 src_install() {
  65         perl-module_src_install
  66         if use examples; then
  67                 docompress -x /usr/share/doc/${PF}/examples
  68                 docinto examples/
  69                 dodoc -r examples/*
  70         fi
  71         if use emacs; then
  72                 ewarn "USE=emacs: perlcritic-mode is broken upstream, but is installed anyway"
  73                 ewarn " https://github.com/Perl-Critic/Perl-Critic/issues/682"
  74                 elisp-install ${PN} extras/perlcritic.{el,elc}
  75                 elisp-site-file-install "${FILESDIR}/${SITEFILE}"
  76         fi
  77 }
  78 pkg_postinst() {
  79         use emacs && elisp-site-regen
  80 }
  81 pkg_postrm() {
  82         use emacs && elisp-site-regen
  83 }