dev-perl/GD/GD-2.560.0-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 DIST_AUTHOR=LDS
   7 DIST_VERSION=2.56
   8 inherit perl-module
   9
  10 DESCRIPTION="Interface to Thomas Boutell's gd library"
  11
  12 SLOT="0"
  13 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
  14 IUSE="animgif gif jpeg png truetype xpm"
  15 PATCHES=(
  16         "${FILESDIR}/${P}-rt106594.patch"
  17 )
  18 RDEPEND="
  19         virtual/perl-Math-Complex
  20         >=media-libs/gd-2.2.3
  21         png? (
  22                 media-libs/gd[png]
  23                 media-libs/libpng:0
  24                 sys-libs/zlib
  25         )
  26         jpeg? (
  27                 media-libs/gd[jpeg]
  28                 virtual/jpeg:0
  29         )
  30         truetype? (
  31                 media-libs/gd[truetype]
  32                 media-libs/freetype:2
  33         )
  34         xpm? (
  35                 media-libs/gd[xpm]
  36                 x11-libs/libXpm
  37         )
  38         gif? ( media-libs/giflib )
  39 "
  40 DEPEND="${RDEPEND}
  41         virtual/perl-ExtUtils-CBuilder
  42         virtual/perl-ExtUtils-MakeMaker
  43 "
  44
  45 PREFER_BUILDPL="no"
  46
  47 src_prepare() {
  48         perl-module_src_prepare
  49
  50         # bug 572000
  51         ln -s "${S}"/lib/GD.xs "${S}"/GD.xs
  52
  53         sed -i "s/use Getopt::Long;/use Getopt::Long qw(:config pass_through);/" \
  54                 "${S}"/Makefile.PL || die
  55 }
  56
  57 src_configure() {
  58         local myconf
  59         myconf="VERSION_33,GD_UNCLOSEDPOLY,GD_FTCIRCLE" # Per line 284 of Makefile.PL
  60         use gif && use animgif && myconf+=",ANIMGIF"
  61         use jpeg && myconf+=",JPEG"
  62         use truetype && myconf+=",FT"
  63         use png && myconf+=",PNG"
  64         use xpm && myconf+=",XPM"
  65         use gif && myconf+=",GIF"
  66         myconf="-options '${myconf}'"
  67         perl-module_src_configure
  68 }
  69
  70 mydoc="GD.html"