dev-perl/Dist-Zilla-Plugin-ReversionOnRelease/Dist-Zilla-Plugin-ReversionOnRelease-0.60.0.ebuild

   1 # Copyright 2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DIST_AUTHOR=MIYAGAWA
   7 DIST_VERSION=0.06
   8 inherit perl-module
   9
  10 DESCRIPTION="Bump and reversion \$VERSION on release"
  11 SLOT="0"
  12 KEYWORDS="~amd64 ~x86"
  13 IUSE="test"
  14 RESTRICT="!test? ( test )"
  15 RDEPEND="
  16         >=dev-perl/Dist-Zilla-4.200.0
  17         >=dev-perl/Version-Next-0.2.0
  18 "
  19 DEPEND="
  20         dev-perl/Module-Build-Tiny
  21 "
  22 BDEPEND="${RDEPEND}
  23         >=dev-perl/Module-Build-Tiny-0.34.0
  24         test? (
  25                 >=virtual/perl-Test-Simple-0.880.0
  26         )
  27 "
  28 PERL_RM_FILES=(
  29         "t/author-pod-syntax.t"
  30 )
  31 src_test() {
  32         local MODULES=(
  33                 "Dist::Zilla::Plugin::ReversionOnRelease ${DIST_VERSION}"
  34         )
  35         local failed=()
  36         for dep in "${MODULES[@]}"; do
  37                 ebegin "Compile testing ${dep}"
  38                         perl -Mblib="${S}" -M"${dep} ()" -e1
  39                 eend $? || failed+=( "${dep}" )
  40         done
  41         if [[ ${failed[@]} ]]; then
  42                 echo
  43                 eerror "One or more modules failed compile:";
  44                 for dep in "${failed[@]}"; do
  45                         eerror "  ${dep}"
  46                 done
  47                 die "Failing due to module compilation errors";
  48         fi
  49         # Note: Not adding plugin VersionFromModule as it requires
  50         # Dist-Zilla-Plugins-CJM.... which is yuuge.
  51         perl-module_src_test
  52 }