dev-perl/Data-ICal/Data-ICal-0.220.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 MODULE_AUTHOR=ALEXMV
   7 MODULE_VERSION=0.22
   8 inherit perl-module
   9
  10 DESCRIPTION="Generates iCalendar (RFC 2445) calendar files"
  11
  12 SLOT="0"
  13 KEYWORDS="amd64 ~x86"
  14 IUSE="test"
  15 RESTRICT="!test? ( test )"
  16
  17 RDEPEND="
  18         dev-perl/Class-Accessor
  19         dev-perl/Class-ReturnValue
  20         dev-perl/Text-vFile-asData
  21 "
  22 DEPEND="${RDEPEND}
  23         >=virtual/perl-ExtUtils-MakeMaker-6.360.0
  24         test? (
  25                 dev-perl/Test-Warn
  26                 dev-perl/Test-NoWarnings
  27                 dev-perl/Test-LongString
  28                 virtual/perl-Test-Simple
  29         )
  30 "
  31
  32 SRC_TEST="do"
  33
  34 src_prepare() {
  35         sed -i "/^auto_install();/d" "${S}"/Makefile.PL || die
  36         sed -i -e 's/use inc::Module::Install;/use lib q[.];\nuse inc::Module::Install;/' Makefile.PL ||
  37                 die "Can't patch Makefile.PL for 5.26 dot-in-inc"
  38         perl-module_src_prepare
  39 }
  40
  41 src_test() {
  42         perl_rm_files t/pod.t t/pod-coverage.t
  43         perl-module_src_test
  44 }