dev-perl/DBD-Pg/DBD-Pg-3.5.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 DIST_AUTHOR=TURNSTEP
   7 inherit perl-module
   8
   9 DESCRIPTION="PostgreSQL database driver for the DBI module"
  10
  11 SLOT="0"
  12 KEYWORDS="~alpha amd64 arm hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
  13 IUSE=""
  14
  15 RDEPEND="
  16         virtual/perl-version
  17         >=dev-perl/DBI-1.614.0
  18         dev-db/postgresql:*
  19 "
  20 DEPEND="${RDEPEND}
  21         virtual/perl-ExtUtils-MakeMaker
  22 "
  23
  24 # testcases require a local database with an
  25 # open password for the postgres user.
  26 DIST_TEST="skip"
  27
  28 src_prepare() {
  29         postgres_include="$(readlink -f "${EPREFIX}"/usr/include/postgresql)"
  30         postgres_lib="${postgres_include//include/lib}"
  31         # Fall-through case is the non-split postgresql
  32         # The active cases instead get us the matching libdir for the includedir.
  33         for i in lib lib64 ; do
  34                 if [ -d "${postgres_lib}/${i}" ]; then
  35                         postgres_lib="${postgres_lib}/${i}"
  36                         break
  37                 fi
  38         done
  39
  40         # env variables for compilation:
  41         export POSTGRES_INCLUDE="${postgres_include}"
  42         export POSTGRES_LIB="${postgres_lib}"
  43         perl-module_src_prepare
  44 }