dev-perl/Bio-SamTools/Bio-SamTools-1.430.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DIST_AUTHOR=LDS
   7 DIST_VERSION=1.43
   8 inherit perl-module toolchain-funcs multilib
   9
  10 DESCRIPTION="Read SAM/BAM database files"
  11
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 LICENSE="|| ( Apache-2.0 Artistic-2 GPL-1+ )"
  15
  16 RDEPEND="
  17         >=sci-biology/bioperl-1.6.9
  18         sci-biology/samtools:0.1-legacy=
  19 "
  20 DEPEND="
  21         dev-perl/Module-Build
  22         sci-biology/samtools:0.1-legacy=
  23 "
  24 BDEPEND="${RDEPEND}
  25         virtual/perl-ExtUtils-CBuilder
  26         >=dev-perl/Module-Build-0.420.0
  27 "
  28
  29 PATCHES=(
  30         "${FILESDIR}"/${PN}-1.430.0-legacy-r1.patch
  31 )
  32
  33 src_configure() {
  34         tc-export CC
  35         SAM_LIB="${EPREFIX}/usr/$(get_libdir)/libbam-0.1-legacy.so" \
  36                 SAM_INCLUDE="${EPREFIX}/usr/include/bam-0.1-legacy" \
  37                 perl-module_src_configure
  38 }