dev-ml/ocamlbuild/ocamlbuild-0.14.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 DESCRIPTION="Generic build tool with built-in rules for building OCaml library and programs"
   7 HOMEPAGE="https://github.com/ocaml/ocamlbuild"
   8 SRC_URI="https://github.com/ocaml/ocamlbuild/archive/${PV}.tar.gz -> ${P}.tar.gz"
   9
  10 LICENSE="LGPL-2.1-with-linking-exception"
  11 SLOT="0/${PV}"
  12 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
  13 IUSE="+ocamlopt test"
  14 RESTRICT="!test? ( test )"
  15
  16 DEPEND=">=dev-lang/ocaml-4.02.3-r1:=[ocamlopt?]"
  17 RDEPEND="${DEPEND}
  18         !<dev-ml/findlib-1.6.1-r1
  19 "
  20 DEPEND="${DEPEND}
  21         test? ( dev-ml/findlib )"
  22
  23 src_configure() {
  24         emake -f configure.make Makefile.config \
  25                 PREFIX="${EPREFIX}/usr" \
  26                 BINDIR="${EPREFIX}/usr/bin" \
  27                 LIBDIR="$(ocamlc -where)" \
  28                 OCAML_NATIVE=$(usex ocamlopt true false) \
  29                 OCAML_NATIVE_TOOLS=$(usex ocamlopt true false) \
  30                 NATDYNLINK=$(usex ocamlopt true false)
  31 }
  32
  33 src_install() {
  34         emake CHECK_IF_PREINSTALLED=false DESTDIR="${D}" install
  35         dodoc Changes
  36 }