dev-ml/llvm-ocaml/llvm-ocaml-8.0.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 : ${CMAKE_MAKEFILE_GENERATOR:=ninja}
   7 # (needed due to CMAKE_BUILD_TYPE != Gentoo)
   8 CMAKE_MIN_VERSION=3.7.0-r1
   9 PYTHON_COMPAT=( python2_7 )
  10
  11 inherit cmake-utils llvm multiprocessing python-any-r1
  12
  13 MY_P=llvm-${PV/_/}.src
  14 DESCRIPTION="OCaml bindings for LLVM"
  15 HOMEPAGE="https://llvm.org/"
  16 SRC_URI="https://github.com/llvm/llvm-project/releases/download/llvmorg-${PV}/${MY_P}.tar.xz"
  17
  18 # Keep in sync with sys-devel/llvm
  19 ALL_LLVM_TARGETS=( AArch64 AMDGPU ARM BPF Hexagon Lanai Mips MSP430
  20         NVPTX PowerPC Sparc SystemZ WebAssembly X86 XCore )
  21 ALL_LLVM_TARGETS=( "${ALL_LLVM_TARGETS[@]/#/llvm_targets_}" )
  22 LLVM_TARGET_USEDEPS=${ALL_LLVM_TARGETS[@]/%/?}
  23
  24 LICENSE="UoI-NCSA"
  25 SLOT="0/${PV}"
  26 KEYWORDS="~amd64 ~arm ~x86"
  27 IUSE="debug test ${ALL_LLVM_TARGETS[*]}"
  28 RESTRICT="!test? ( test )"
  29
  30 RDEPEND="
  31         >=dev-lang/ocaml-4.00.0:0=
  32         dev-ml/ocaml-ctypes:=
  33         ~sys-devel/llvm-${PV}:=[${LLVM_TARGET_USEDEPS// /,},debug?]
  34         !sys-devel/llvm[ocaml(-)]"
  35 # configparser-3.2 breaks the build (3.3 or none at all are fine)
  36 DEPEND="${RDEPEND}
  37         dev-lang/perl
  38         dev-ml/findlib
  39         test? ( dev-ml/ounit )
  40         !!<dev-python/configparser-3.3.0.2
  41         ${PYTHON_DEPS}"
  42
  43 REQUIRED_USE="${PYTHON_REQUIRED_USE}
  44         || ( ${ALL_LLVM_TARGETS[*]} )"
  45
  46 S=${WORKDIR}/${MY_P}
  47
  48 # least intrusive of all
  49 CMAKE_BUILD_TYPE=RelWithDebInfo
  50
  51 pkg_setup() {
  52         LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
  53         python-any-r1_pkg_setup
  54 }
  55
  56 src_prepare() {
  57         # Python is needed to run tests using lit
  58         python_setup
  59
  60         cmake-utils_src_prepare
  61 }
  62
  63 src_configure() {
  64         local libdir=$(get_libdir)
  65         local mycmakeargs=(
  66                 -DLLVM_LIBDIR_SUFFIX=${libdir#lib}
  67
  68                 -DBUILD_SHARED_LIBS=ON
  69                 -DLLVM_OCAML_OUT_OF_TREE=ON
  70                 -DLLVM_TARGETS_TO_BUILD="${LLVM_TARGETS// /;}"
  71                 -DLLVM_BUILD_TESTS=$(usex test)
  72
  73                 # disable various irrelevant deps and settings
  74                 -DLLVM_ENABLE_FFI=OFF
  75                 -DLLVM_ENABLE_TERMINFO=OFF
  76                 -DHAVE_HISTEDIT_H=NO
  77                 -DWITH_POLLY=OFF
  78                 -DLLVM_ENABLE_ASSERTIONS=$(usex debug)
  79                 -DLLVM_ENABLE_EH=ON
  80                 -DLLVM_ENABLE_RTTI=ON
  81
  82                 -DLLVM_HOST_TRIPLE="${CHOST}"
  83
  84                 # disable go bindings
  85                 -DGO_EXECUTABLE=GO_EXECUTABLE-NOTFOUND
  86
  87                 # TODO: ocamldoc
  88         )
  89
  90         use test && mycmakeargs+=(
  91                 -DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
  92         )
  93
  94         # LLVM_ENABLE_ASSERTIONS=NO does not guarantee this for us, #614844
  95         # also: custom rules for OCaml do not work for CPPFLAGS
  96         use debug || local -x CFLAGS="${CFLAGS} -DNDEBUG"
  97         cmake-utils_src_configure
  98
  99         local llvm_libdir=$(llvm-config --libdir)
 100         # an ugly hack; TODO: figure out a way to pass -L to ocaml...
 101         cd "${BUILD_DIR}/${libdir}" || die
 102         ln -s "${llvm_libdir}"/*.so . || die
 103
 104         if use test; then
 105                 local llvm_bindir=$(llvm-config --bindir)
 106                 # Force using system-installed tools.
 107                 sed -i -e "/llvm_tools_dir/s@\".*\"@\"${llvm_bindir}\"@" \
 108                         "${BUILD_DIR}"/test/lit.site.cfg.py || die
 109         fi
 110 }
 111
 112 src_compile() {
 113         cmake-utils_src_compile ocaml_all
 114 }
 115
 116 src_test() {
 117         # respect TMPDIR!
 118         local -x LIT_PRESERVES_TMP=1
 119         cmake-utils_src_make check-llvm-bindings-ocaml
 120 }
 121
 122 src_install() {
 123         DESTDIR="${D}" \
 124         cmake -P "${BUILD_DIR}"/bindings/ocaml/cmake_install.cmake || die
 125
 126         dodoc bindings/ocaml/README.txt
 127 }