dev-lua/LuaBitOp/LuaBitOp-1.0.2-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 inherit toolchain-funcs multilib-minimal
   6
   7 DESCRIPTION="Bit Operations Library for the Lua Programming Language"
   8 HOMEPAGE="http://bitop.luajit.org"
   9 SRC_URI="http://bitop.luajit.org/download/${P}.tar.gz"
  10
  11 LICENSE="MIT"
  12 SLOT="0"
  13 KEYWORDS="amd64 ~arm ~arm64 ~hppa ~mips ppc ppc64 sparc x86"
  14 IUSE=""
  15
  16 RDEPEND=">=dev-lang/lua-5.1.5-r2:*[${MULTILIB_USEDEP}]"
  17 DEPEND="${RDEPEND}
  18         >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]"
  19
  20 src_prepare() {
  21         multilib_copy_sources
  22 }
  23
  24 multilib_src_compile()
  25 {
  26         emake CC="$(tc-getCC)" INCLUDES= CCOPT=
  27 }
  28
  29 multilib_src_test() {
  30         # tests use native lua interpreter
  31         multilib_is_native_abi && default
  32 }
  33
  34 multilib_src_install()
  35 {
  36         local instdir="$($(tc-getPKG_CONFIG) --variable INSTALL_CMOD lua)"
  37         exeinto "${instdir#${EPREFIX}}"
  38         doexe bit.so
  39 }
  40
  41 multilib_src_install_all() {
  42         dodoc README
  43         dohtml -r doc/.
  44 }