dev-libs/xmlsec/xmlsec-1.2.20.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils autotools
   8
   9 DESCRIPTION="Command line tool for signing, verifying, encrypting and decrypting XML"
  10 HOMEPAGE="http://www.aleksey.com/xmlsec"
  11 SRC_URI="http://www.aleksey.com/xmlsec/download/${PN}1-${PV}.tar.gz"
  12
  13 LICENSE="MIT"
  14 SLOT="0"
  15 KEYWORDS="amd64 ppc ~ppc64 ~sparc x86"
  16 IUSE="doc gcrypt gnutls nss +openssl static-libs"
  17 REQUIRED_USE="|| ( gcrypt gnutls nss openssl )
  18         gnutls? ( gcrypt )"
  19
  20 RDEPEND=">=dev-libs/libxml2-2.7.4
  21         >=dev-libs/libxslt-1.0.20
  22         gcrypt? ( >=dev-libs/libgcrypt-1.4.0:0 )
  23         gnutls? ( >=net-libs/gnutls-2.8.0 )
  24         nss? (
  25                 >=dev-libs/nspr-4.4.1
  26                 >=dev-libs/nss-3.9
  27         )
  28         openssl? ( >=dev-libs/openssl-0.9.7:* )"
  29 DEPEND="${RDEPEND}
  30         virtual/pkgconfig"
  31
  32 S=${WORKDIR}/${PN}1-${PV}
  33
  34 src_prepare() {
  35         # conditionally install extra documentation
  36         if ! use doc ; then
  37                 sed -i '/^SUBDIRS/s/docs//' Makefile.am || die
  38                 eautoreconf
  39         fi
  40 }
  41
  42 src_configure() {
  43         econf \
  44                 $(use_enable static-libs static) \
  45                 $(use_with gcrypt gcrypt "") \
  46                 $(use_with gnutls gnutls "") \
  47                 $(use_with nss nspr "") \
  48                 $(use_with nss nss "") \
  49                 $(use_enable openssl aes) \
  50                 $(use_with openssl openssl "") \
  51                 --enable-pkgconfig \
  52                 --enable-xkms \
  53                 --with-html-dir=/usr/share/doc/${PF}/html
  54 }
  55
  56 src_test() {
  57         emake TMPFOLDER="${T}" check
  58 }
  59
  60 src_install() {
  61         default
  62         prune_libtool_files
  63 }