dev-libs/totem-pl-parser/totem-pl-parser-3.26.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit gnome.org meson xdg
   6
   7 DESCRIPTION="Playlist parsing library"
   8 HOMEPAGE="https://developer.gnome.org/totem-pl-parser/stable/"
   9
  10 LICENSE="LGPL-2+"
  11 SLOT="0/18"
  12 IUSE="archive crypt gtk-doc +introspection +quvi test"
  13 RESTRICT="!test? ( test )"
  14 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc x86"
  15
  16 RDEPEND="
  17         >=dev-libs/glib-2.56:2
  18         quvi? ( >=media-libs/libquvi-0.9.1:0= )
  19         archive? ( >=app-arch/libarchive-3:0= )
  20         dev-libs/libxml2:2
  21         crypt? ( dev-libs/libgcrypt:0= )
  22         introspection? ( >=dev-libs/gobject-introspection-1.54:= )
  23 "
  24 DEPEND="${RDEPEND}"
  25 BDEPEND="
  26         dev-util/glib-utils
  27         gtk-doc? (
  28                 >=dev-util/gtk-doc-1.14
  29                 app-text/docbook-xml-dtd:4.3 )
  30         >=sys-devel/gettext-0.19.8
  31         virtual/pkgconfig
  32         test? (
  33                 gnome-base/gvfs[http]
  34                 sys-apps/dbus )
  35 "
  36
  37 src_prepare() {
  38         # Disable tests requiring network access, bug #346127
  39         # 3rd test fails on upgrade, not once installed
  40         # Leio: I consider network tests important for ensuring full functionality, thus trying with them again */
  41         #sed -e 's:\(g_test_add_func.*/parser/resolution.*\):/*\1*/:' \
  42         #       -e 's:\(g_test_add_func.*/parser/parsing/itms_link.*\):/*\1*/:' \
  43         #       -e 's:\(g_test_add_func.*/parser/parsability.*\):/*\1*/:'\
  44         #       -i plparse/tests/parser.c || die "sed failed"
  45
  46         xdg_src_prepare
  47 }
  48
  49 src_configure() {
  50         # uninstalled-tests is abused to switch from loading live FS helper
  51         # to in-build-tree helper, check on upgrades this is not having other
  52         # consequences, bug #630242
  53         local emesonargs=(
  54                 -Denable-quvi=$(usex quvi yes no)
  55                 -Denable-libarchive=$(usex archive yes no)
  56                 -Denable-libgcrypt=$(usex crypt yes no)
  57                 $(meson_use gtk-doc enable-gtk-doc)
  58                 $(meson_use introspection)
  59         )
  60         meson_src_configure
  61 }
  62
  63 src_test() {
  64         # This is required as told by upstream in bgo#629542
  65         GVFS_DISABLE_FUSE=1 dbus-run-session meson test -C "${BUILD_DIR}"
  66 }