dev-libs/totem-pl-parser/totem-pl-parser-3.10.5.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7
   8 inherit gnome2
   9
  10 DESCRIPTION="Playlist parsing library"
  11 HOMEPAGE="https://developer.gnome.org/totem-pl-parser/stable/"
  12
  13 LICENSE="LGPL-2+"
  14 SLOT="0/18"
  15 IUSE="archive crypt +introspection +quvi test"
  16 KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86 ~x86-fbsd"
  17
  18 RDEPEND="
  19         >=dev-libs/glib-2.31:2
  20         dev-libs/gmime:2.6
  21         >=net-libs/libsoup-2.43:2.4
  22         archive? ( >=app-arch/libarchive-3 )
  23         crypt? ( dev-libs/libgcrypt:0= )
  24         introspection? ( >=dev-libs/gobject-introspection-0.9.5:= )
  25         quvi? ( >=media-libs/libquvi-0.9.1:0= )
  26 "
  27 DEPEND="${RDEPEND}
  28         !<media-video/totem-2.21
  29         >=dev-util/intltool-0.35
  30         >=dev-util/gtk-doc-am-1.14
  31         >=sys-devel/gettext-0.17
  32         virtual/pkgconfig
  33         test? (
  34                 gnome-base/gvfs[http]
  35                 sys-apps/dbus )
  36 "
  37 # eautoreconf needs:
  38 #       dev-libs/gobject-introspection-common
  39 #       >=gnome-base/gnome-common-3.6
  40
  41 src_prepare() {
  42         # Disable tests requiring network access, bug #346127
  43         # 3rd test fails on upgrade, not once installed
  44         sed -e 's:\(g_test_add_func.*/parser/resolution.*\):/*\1*/:' \
  45                 -e 's:\(g_test_add_func.*/parser/parsing/itms_link.*\):/*\1*/:' \
  46                 -e 's:\(g_test_add_func.*/parser/parsability.*\):/*\1/:'\
  47                 -i plparse/tests/parser.c || die "sed failed"
  48
  49         gnome2_src_prepare
  50 }
  51
  52 src_configure() {
  53         gnome2_src_configure \
  54                 --disable-static \
  55                 $(use_enable archive libarchive) \
  56                 $(use_enable crypt libgcrypt) \
  57                 $(use_enable quvi) \
  58                 $(use_enable introspection)
  59 }
  60
  61 src_test() {
  62         # This is required as told by upstream in bgo#629542
  63         GVFS_DISABLE_FUSE=1 dbus-launch emake check || die "emake check failed"
  64 }