dev-libs/rasqal/rasqal-0.9.33.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit libtool
   7
   8 DESCRIPTION="Library that handles Resource Description Framework (RDF)"
   9 HOMEPAGE="http://librdf.org/rasqal/"
  10 SRC_URI="http://download.librdf.org/source/${P}.tar.gz"
  11
  12 LICENSE="Apache-2.0 GPL-2 LGPL-2.1"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  15 IUSE="+crypt gmp kernel_linux +mhash pcre static-libs test xml"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         >=media-libs/raptor-2.0.15
  20         crypt? (
  21                 !mhash? ( dev-libs/libgcrypt:0 )
  22                 mhash? ( app-crypt/mhash )
  23         )
  24         !gmp? ( dev-libs/mpfr:= )
  25         gmp? ( dev-libs/gmp:= )
  26         kernel_linux? ( >=sys-apps/util-linux-2.19 )
  27         pcre? ( dev-libs/libpcre )
  28         xml? ( dev-libs/libxml2 )
  29 "
  30 DEPEND="${RDEPEND}"
  31 BDEPEND="
  32         >=sys-devel/bison-3
  33         >=sys-devel/flex-2.5.36
  34         virtual/pkgconfig
  35         test? ( dev-perl/XML-DOM )
  36 "
  37
  38 DOCS=( AUTHORS ChangeLog NEWS README )
  39 HTML_DOCS=( {NEWS,README,RELEASE}.html )
  40
  41 src_prepare() {
  42         default
  43         elibtoolize # g/fbsd .so versioning
  44 }
  45
  46 src_configure() {
  47         # FIXME: From 0.9.27 to .28 --with-random-approach= was introduced, do we
  48         # need a logic for it? Perhaps for dev-libs/gmp?
  49         local myeconfargs=(
  50                 --with-decimal=$(usex gmp gmp mpfr)
  51                 --with-uuid-library=$(usex kernel_linux libuuid internal)
  52                 $(use_enable pcre)
  53                 --with-regex-library=$(usex pcre pcre posix)
  54                 $(use_enable static-libs static)
  55                 $(use_enable xml xml2)
  56         )
  57
  58         if use crypt; then
  59                 myeconfargs+=( --with-digest-library=$(usex mhash mhash gcrypt) )
  60         else
  61                 myeconfargs+=( --with-digest-library=internal )
  62         fi
  63
  64         econf "${myeconfargs[@]}"
  65 }
  66
  67 src_install() {
  68         default
  69         find "${D}" -name '*.la' -delete || die
  70 }