dev-libs/pslib/pslib-0.4.5.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=4
   6
   7 inherit eutils autotools
   8
   9 DESCRIPTION="pslib is a C-library to create PostScript files on the fly"
  10 HOMEPAGE="http://pslib.sourceforge.net/"
  11 SRC_URI="mirror://sourceforge/pslib/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
  16 IUSE="debug jpeg png static-libs tiff"
  17
  18 RDEPEND="
  19         png? ( >=media-libs/libpng-1.2.43-r2:0 )
  20         jpeg? ( virtual/jpeg )
  21         tiff? ( media-libs/tiff )"
  22 #gif? requires libungif, not in portage
  23 DEPEND="${RDEPEND}
  24         dev-lang/perl
  25         >=dev-libs/glib-2
  26         dev-util/intltool
  27         dev-perl/XML-Parser"
  28
  29 src_prepare() {
  30         # hackpatchfix underlinking
  31         sed -i -e 's/$(TIFF_LIBS)/$(TIFF_LIBS) -lm/' src/Makefile.am || die
  32         sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.in || die
  33         eautoreconf
  34 }
  35
  36 src_configure() {
  37         econf \
  38                 --enable-bmp \
  39                 $(use_enable static-libs static) \
  40                 $(use_with png) \
  41                 $(use_with jpeg) \
  42                 $(use_with tiff) \
  43                 $(use_with debug)
  44 }
  45
  46 src_install() {
  47         default
  48
  49         prune_libtool_files --all
  50 }