dev-libs/openobex/openobex-1.5.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit eutils autotools
   8
   9 DESCRIPTION="An implementation of the OBEX protocol used for transferring data to mobile devices"
  10 HOMEPAGE="https://sourceforge.net/projects/openobex/"
  11 SRC_URI="mirror://kernel/linux/bluetooth/${P}.tar.gz"
  12
  13 LICENSE="GPL-2 LGPL-2.1"
  14 SLOT="0"
  15 KEYWORDS="amd64 arm hppa ppc ppc64 sparc x86"
  16 IUSE="bluetooth debug irda syslog usb"
  17
  18 RDEPEND="bluetooth? ( net-wireless/bluez )
  19         usb? ( virtual/libusb:0 )"
  20 DEPEND="${RDEPEND}
  21         virtual/pkgconfig"
  22
  23 src_prepare() {
  24         epatch "${FILESDIR}"/${P}-use-flags.patch
  25         sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.ac || die
  26         eautoreconf
  27 }
  28
  29 src_configure() {
  30         econf \
  31                 --enable-apps \
  32                 $(use_enable irda) \
  33                 $(use_enable bluetooth) \
  34                 $(use_enable usb) \
  35                 $(use_enable debug) \
  36                 $(use_enable debug dump) \
  37                 $(use_enable syslog)
  38 }
  39
  40 src_install() {
  41         emake DESTDIR="${D}" install || die "make install failed"
  42         dodoc README AUTHORS NEWS ChangeLog
  43 }